# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=(parabolaweb-utils parabolaweb-dev)
pkgver=20180326
pkgdesc="Utilities for managing the ParabolaWeb website application"
url="https://git.parabola.nu/packages/parabolaweb-utils.git/"
license=('GPL2')

# The commit to get dependency info for
# Bump pkgrel instead of pkgver if updating this is the only change
_parabolaweb_commit=2f35bd492629a52f4849c379f02030c1efb2495c

pkgrel=1
epoch=1
arch=('i686' 'x86_64' 'armv7h')

source=("https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig}
	"requirements_prod-${_parabolaweb_commit}.txt::https://projects.parabolagnulinux.org/parabolaweb.git/plain/requirements_prod.txt?id=${_parabolaweb_commit}")
md5sums=('151aa82ec449de60f75ca41a64a8f7fa'
         'SKIP'
         '2a282dc52fb6cf3c4907715a2e85dc7b')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

build() {
	cd "$srcdir/$pkgname-$pkgver"
	prod_file="file://${srcdir}/requirements_prod-${_parabolaweb_commit}.txt" make
}

package_parabolaweb-utils() {
	cd "$srcdir/$pkgbase-$pkgver"
	depends=($(< depends.txt))
	backup=('etc/conf.d/parabolaweb' 'etc/uwsgi/parabolaweb.ini')
	make install DESTDIR="$pkgdir"
}

package_parabolaweb-dev() {
	cd "$srcdir/$pkgbase-$pkgver"
	pkgdesc="Depends on packages needed to develop ParabolaWeb"
	depends=($(sed -r -e 's/\s*#.*//' depends_make.txt))
}