# Maintainer (Arch): David Runge <dvzrv@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Contributor (Arch): Gerardo Exequiel Pozzi <djgera@archlinux.org>
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgbase=parabolaiso
pkgname=(parabolaiso mkinitcpio-parabolaiso)
pkgver=46
pkgrel=1
pkgdesc='Tools for creating Parabola GNU/Linux-libre live and install iso images'
arch=('any')
license=('GPL3')
url='https://projects.parabola.nu/parabolaiso.git/'
provides=("archiso=$pkgver")
conflicts=('archiso')
replaces=(${conflicts[@]})
source=("https://repo.parabola.nu/other/${pkgname}/${pkgname}-v${pkgver}.tar.gz"{,.sig})
sha256sums=('e17be487f4d103070ad6b0af09b376ac5f91d5de5c88090a1457d23dffe4a676'
            'SKIP')
validpgpkeys=(6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78) # David P.

package_parabolaiso() {
  depends=('arch-install-scripts' 'bash' 'dosfstools' 'e2fsprogs' 'libisoburn'
  'squashfs-tools')
  optdepends=('edk2-ovmf: for emulating UEFI with run_archiso'
              'qemu: for run_parabolaiso')
  cd "${pkgbase}-v${pkgver}"
  make DESTDIR="${pkgdir}" install
}

package_mkinitcpio-parabolaiso() {
  pkgdesc='Mkinitcpio hooks and scripts for parabolaiso'
  depends=('mkinitcpio')
  cd "${pkgbase}-v${pkgver}"
  make DESTDIR="${pkgdir}" install-initcpio
}