# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Maintainer (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Contributor (Arch): judd <jvinet@zeroflux.org>

# Rationale for inclusion in [libre]:
#
# Add `depends+=('audit')` as a temporary work-around for a bug in
# Arch Linux 32's `pam`.
#
# https://labs.parabola.nu/issues/2031
# https://bugs.archlinux32.org/index.php?do=details&task_id=54
#
# See also: https://bugs.archlinux.org/task/60365

pkgname=pam
pkgver=1.3.1
pkgrel="1.3.par1"
pkgdesc="PAM (Pluggable Authentication Modules) library"
arch=(i486 i686 pentium3 'x86_64')
license=('GPL2')
url="http://linux-pam.org"
depends=('glibc' 'cracklib' 'libtirpc' 'pambase')
depends+=('audit')
makedepends=('flex' 'w3m' 'docbook-xml>=4.4' 'docbook-xsl')
backup=(etc/security/{access.conf,group.conf,limits.conf,namespace.conf,namespace.init,pam_env.conf,time.conf} etc/default/passwd etc/environment)
source=(https://github.com/linux-pam/linux-pam/releases/download/v$pkgver/Linux-PAM-$pkgver.tar.xz
        https://github.com/linux-pam/linux-pam/releases/download/v$pkgver/Linux-PAM-$pkgver.tar.xz.asc)
validpgpkeys=(
        '8C6BFD92EE0F42EDF91A6A736D1A7F052E5924BB' # Thorsten Kukuk
)

md5sums=('558ff53b0fc0563ca97f79e911822165'
         'SKIP')

options=('!emptydirs')

build() {
  cd $srcdir/Linux-PAM-$pkgver
  ./configure --libdir=/usr/lib --sbindir=/usr/bin --disable-db
  make
}

package() {
  cd $srcdir/Linux-PAM-$pkgver
  make DESTDIR=$pkgdir SCONFIGDIR=/etc/security install

  # set unix_chkpwd uid
  chmod +s $pkgdir/usr/bin/unix_chkpwd

  # remove doc which is not used anymore
  # FS #40749
  rm $pkgdir/usr/share/doc/Linux-PAM/sag-pam_userdb.html
}

unset -f pkgver