# vim: set ts=2 sw=2 et:
# $Id$
# Maintainer (Arch): Dan McGee <dan@archlinux.org>
# Maintainer (Arch): Dave Reisner <dreisner@archlinux.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Nicolás Reynolds <fauno@kiwwwi.com.ar>
# Contributor: Daniel Milewski <niitotantei@riseup.net>

pkgname=pacman
pkgver=5.1.0
pkgrel=2
pkgrel+=.parabola2
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
arch+=('i686' 'armv7h')
url="http://www.archlinux.org/pacman/"
license=('GPL')
groups=('base' 'base-devel')
groups+=('base-openrc')
depends=('bash' 'glibc' 'libarchive' 'curl'
         'gpgme' 'pacman-mirrorlist' 'archlinux-keyring')
depends+=('parabola-keyring' 'archlinuxarm-keyring' 'archlinux32-keyring')
makedepends=('asciidoc')
checkdepends=('python2' 'fakechroot')
optdpepends=('perl-locale-gettext: translation support in makepkg-template')
provides=('pacman-parabola')
conflicts=('pacman-parabola')
replaces=('pacman-parabola')
backup=(etc/pacman.conf etc/makepkg.conf)
options=('strip' 'debug')
validpgpkeys=('6645B0A8C7005E78DB1D7864F99FFE0FEAE999BD'  # Allan McRae <allan@archlinux.org>
              'B8151B117037781095514CA7BBDFFC92306B1121') # Andrew Gregory (pacman) <andrew@archlinux.org>
source=(https://sources.archlinux.org/other/pacman/$pkgname-$pkgver.tar.gz{,.sig}
        0001-makepkg-Clear-ERR-trap-before-trying-to-restore-it.patch
        0002-makepkg-Don-t-use-parameterless-return.patch
        "${arch[@]/#/pacman.conf.}"
        makepkg.conf.in
        pacman-keyring.service
        pacman-keyring.timer
        0001-Sychronize-filesystem.patch
        0002-Revert-close-stdin-before-running-install-scripts.patch
        0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch
        0001-makepkg-treat-pkgrel-more-similarly-to-pkgver.patch
        0001-Revert-makepkg-use-the-declare-builtin-when-backing-.patch)
sha256sums=('9f5993fc8923530713742f15df284677f297b3eca15ed7a24758c98ac7399bd3'
            'SKIP'
            '9b2304141582a421e812c76760a74f360a3cbd780472cbb60cf023a34d6fcb3d'
            '2a31d4db5f6e19e0148d4892de14317514f2b2dfb5369c7972a641ca8be89e5a'
            '1b2c8f4ec84d0dc496516880a54b5e4deb78798618c9cf5e284a45303f156e58'
            '19853ea9a2138157bbb334eb7f3a9b3098b88e513678b54b7b4f19d2ffd6ecad'
            'b2cb3ba229edba338c0af7d7f5bb1a6ef6143bcd453c693bfee0c02fa1cfa18a'
            'ecef1e98eaaf207f4f2c3d07cfe13533866e1e774240eb833e8b3bd691ada95f'
            '220f1b25a64727041dc6fa3fd486b0a043f735a3f6cecedc4e2f7c47ec6ce66d'
            '2a857061f032ff5485f5c75ab74e6f6532621e08963ef48640a792cca16cacd6'
            '635ef682073878b6273e3376b00a89a572c4f5f39b118f7b0b4c7497a265a16c'
            'e9e63a58ba7022869b001f4badbfcf340c47c19ab345c77bef3b2287cf9045fd'
            '94e6771cc47ba0bd19f67f2c866dfd0336560e89ee72b4af373a20d3ae1abab7'
            '91bdcb8b29cc75a2e9f0fe821c1599fec2736a5115308ad502d309f04f3320a2'
            'a00d733c89869afe58a6c54f22c18c2d700c57e887db5f0ca7d3ef61b7baf355')

prepare() {
  cd "$pkgname-$pkgver"
  # Fix install_packages failure exit code, required by makechrootpkg
  patch -Np1 -i ../0001-makepkg-Clear-ERR-trap-before-trying-to-restore-it.patch
  patch -Np1 -i ../0002-makepkg-Don-t-use-parameterless-return.patch

  # From Arch ARM
  if [ "${CARCH}" = "armv7h" ]; then
    patch -p1 -i $srcdir/0001-Sychronize-filesystem.patch
    patch -p1 -i $srcdir/0002-Revert-close-stdin-before-running-install-scripts.patch
    patch -p1 -i $srcdir/0003-Revert-alpm_run_chroot-always-connect-parent2child-p.patch
  fi

  # From Parabola
  patch -p1 -i $srcdir/0001-makepkg-treat-pkgrel-more-similarly-to-pkgver.patch
  # Actually from upstream git/ML, but actually worth backporting in
  # Parabola because we build debug packages by default
  patch -p1 -i $srcdir/0001-Revert-makepkg-use-the-declare-builtin-when-backing-.patch
}

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --sysconfdir=/etc \
    --localstatedir=/var --enable-doc \
    --with-scriptlet-shell=/usr/bin/bash \
    --with-ldconfig=/usr/bin/ldconfig
  make V=1

  # Generate the architecture-specific makepkg.conf files
  local carch mycarch mychost myflags myldflags
  for carch in "${arch[@]}"; do
    case $carch in
      i686)
        mycarch="i686"
        mychost="i686-pc-linux-gnu"
        myflags="-march=i686 -mtune=generic -O2 -pipe -fstack-protector-strong -fno-plt"
        ;;
      x86_64)
        mycarch="x86_64"
        mychost="x86_64-pc-linux-gnu"
        myflags="-march=x86-64 -mtune=generic -O2 -pipe -fstack-protector-strong -fno-plt"
        ;;
      armv7h)
        mycarch="armv7h"
        mychost="armv7l-unknown-linux-gnueabihf"
        myflags="-march=armv7-a -mfloat-abi=hard -mfpu=vfpv3-d16 -O2 -pipe -fstack-protector-strong -fno-plt"
        ;;
    esac
    myldflags="-Wl,-O1,--sort-common,--as-needed,-z,relro,-z,now"

    # set things correctly in the default conf file
    sed < "$srcdir/makepkg.conf.in" > "$srcdir/makepkg.conf.$carch" \
        -e "s|@CARCH[@]|$mycarch|g" \
        -e "s|@CHOST[@]|$mychost|g" \
        -e "s|@LDFLAGS[@]|$myldflags|g" \
        -e "s|@CARCHFLAGS[@]|$myflags|g"
  done
}

check() {
  make -C "$pkgname-$pkgver" check
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  # install distro-specific stuff
  install -dm755 "$pkgdir/etc"
  install -m644 "$srcdir/pacman.conf.$CARCH" "$pkgdir/etc/pacman.conf"
  install -m644 "$srcdir/makepkg.conf.$CARCH" "$pkgdir/etc/makepkg.conf"

  install -dm755 "$pkgdir/usr/share/pacman/defaults"
  local carch
  for carch in "${arch[@]}"; do
    install -m644 "$srcdir/pacman.conf.$carch" "$pkgdir/usr/share/pacman/defaults/"
    install -m644 "$srcdir/makepkg.conf.$carch" "$pkgdir/usr/share/pacman/defaults/"
  done

  # put bash_completion in the right location
  install -dm755 "$pkgdir/usr/share/bash-completion/completions"
  mv "$pkgdir/etc/bash_completion.d/pacman" "$pkgdir/usr/share/bash-completion/completions"
  rmdir "$pkgdir/etc/bash_completion.d"

  for f in makepkg pacman-key; do
    ln -s pacman "$pkgdir/usr/share/bash-completion/completions/$f"
  done

  # Parabola's pacman began shipping a weekly job for this back in
  # 2014.  Why is it nescessary for Parabola installs, but it
  # seemingly isn't for Arch installs?
  install -Dm644 "$srcdir/pacman-keyring.service" "$pkgdir/usr/lib/systemd/system/pacman-keyring.service"
  install -Dm644 "$srcdir/pacman-keyring.timer" "$pkgdir/usr/lib/systemd/system/pacman-keyring.timer"
  install -Dm644 /dev/stdin "$pkgdir/usr/lib/systemd/system-preset/90-pacman.preset" <<<"enable pacman-keyring.timer"
}