# Maintainer (arch): Florian Pritz <bluewind@xinu.at>
# Contributor (arch): Dan McGee <dan@archlinux.org>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Esteban Carnevale <alfplayer@mailoo.org>


# Note: building and publishing this package is a bit delicate
#   1: modify 'mirrorlist.txt' on the repo server
#   2: `makepkg -g` (to get the new checksum)
#   3: set 'pkgver' to YYYYMMDD
#   4: put the new checksum in 'sha256sums'
#   5: `sudo libremakepkg && librestage && librerelease` (to publish the new package)


pkgname=pacman-mirrorlist
pkgver=20210225
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Parabola GNU/Linux-libre mirror list for use by pacman"
arch=('any')
url="https://www.parabola.nu/"
license=('GPL')

backup=(etc/pacman.d/mirrorlist)
source=(mirrorlist-${pkgver}.txt::https://repo.parabola.nu/mirrorlist.txt)

sha256sums=('0799119c19b0ca9b5f6aaaf272964c0728662d1a7f551e91cf34066bb1f6bd72')


prepare()
{
  local dt=$( LC_ALL=C date -u +%Y-%m-%d )

  sed -i "s|\(Last Updated: \).*|\1${dt}|" "${srcdir}"/mirrorlist-${pkgver}.txt
}

package()
{
  mkdir -p "${pkgdir}"/etc/pacman.d
  install -m644 "${srcdir}"/mirrorlist-${pkgver}.txt "${pkgdir}"/etc/pacman.d/mirrorlist
}