# $Id$
# Maintainer (Arch): Vesa Kaihlavirta <vegai@iki.fi>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=openttd
pkgver=1.7.2
pkgrel=3
pkgrel+=.parabola1
pkgdesc='An engine for running Transport Tycoon Deluxe.'
pkgdesc+=' (without nonfree openttd-opensfx recommendation)'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='https://www.openttd.org'
license=('GPL')
depends=('libpng' 'sdl' 'icu' 'fontconfig' 'lzo' 'hicolor-icon-theme' 'desktop-file-utils' 'xz')
depends+=('icu>=61' 'icu<62')
optdepends=('openttd-opengfx: free graphics')
source=("https://binaries.openttd.org/releases/${pkgver}/${pkgname}-${pkgver}-source.tar.xz")
sha256sums=('fe51a0bade8fdf6ce3ec696418ecf75c95783cdcabfd7b204eec5c0bb5d149d4')

build() {
  cd ${pkgname}-${pkgver} 

  # http://site.icu-project.org/download/61#TOC-Migration-Issues
  CXXFLAGS+=' -DU_USING_ICU_NAMESPACE=1'

 ./configure \
    --prefix-dir=/usr \
    --binary-name=${pkgname} \
    --binary-dir=bin \
    --data-dir=share/${pkgname} \
    --install-dir="${pkgdir}" \
    --doc-dir=share/doc/${pkgname} \
    --menu-name="OpenTTD"

  make
}

package() {
  cd ${pkgname}-${pkgver} 

  make install
}