# Contributor (Arch): SpepS <dreamspepser at yahoo dot it>
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=openimageio
pkgver=1.4.12
pkgrel=3.parabola2
pkgdesc='A library for reading and writing images, including classes, utilities, and applications (built for the blender package)'
arch=('i686' 'x86_64' 'mips64el')
url="http://www.$pkgname.org/"
license=('custom')
depends=('boost-libs' 'freetype2' 'glew' 'libtiff' 'libwebp' 'openjpeg' 'openexr') # 'opencolorio'
makedepends=('boost' 'cmake' 'git' 'python2' 'qt4')
optdepends=('qt4: iv image viewer'
            'python2: bindings support')
conflicts=("$pkgname-parabola")
replaces=("$pkgname-parabola")
source=("git://github.com/OpenImageIO/oiio.git#tag=Release-$pkgver")
md5sums=('SKIP')

prepare() {
  cd oiio

  msg 'renaming wrong OS name'
  _OS=$(uname -o)
  [[ $_OS == GNU ]] &&\
    sed -i 's|linux|GNU|i;
           ' src/{cmake/platform.cmake,make/detectplatform.mk}
  [[ $_OS == GNU/Linux ]] &&\
    sed -i 's|[{]uname[}][,]linux]|{uname -o},GNU/Linux|;\|platform| s|linux|GNU/Linux|i
           ' src/{cmake/platform.cmake,make/detectplatform.mk}
  [[ $_OS == GNU/kFreeBSD ]] &&\
    sed -i '\|STREQUAL| s|FreeBSD|kFreeBSD|;\|platform| s|freebsd|GNU/kFreeBSD|i
           ' src/cmake/platform.cmake
    sed -i 's|[{]uname[}][,]linux]|{uname -o},GNU/kFreeBSD|;\|platform| s|linux|GNU/kFreeBSD|i
           ' src/make/detectplatform.mk

  # fix for giflib 5.1
  sed -i 's|DGifCloseFile [(]m_gif_file[)] == GIF_ERROR|DGifCloseFile (m_gif_file, 0) == GIF_ERROR|' src/gif.imageio/gifinput.cpp
}

build() {
  cd oiio

  [[ -d build ]] && rm -r build
  mkdir build && cd build

  cmake .. \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DOIIO_BUILD_TESTS=OFF \
      -DPYLIB_INSTALL_DIR=lib/python2.7/site-packages \
      -DPYLIB_INCLUDE_SONAME=ON \
      -DPYLIB_LIB_PREFIX=OFF
  make
}

package() {
  cd oiio/build

  make DESTDIR=$pkgdir install

  # license
  install -Dm644 ../LICENSE $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: