# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of Arch pkg

pkgname=openimageio
pkgver=1.4.10
pkgrel=1
pkgdesc='A library for reading and writing images, including classes, utilities, and applications (built for the blender-libre package)'
arch=(
  x86_64
  i686
)
url=http://www.openimageio.org/
license=custom
depends=(
  boost-libs
  freetype2
  giflib-lts
  glew
  libjpeg-turbo
  libpng
  libtiff
  libwebp
  opencolorio
  openexr
  openjpeg
  openssl
  zlib
)
makedepends=(
  git
  boost
  cmake
  python2
  qt4
)
optdepends=(
  'qt4: iv image viewer'
  'python2: bindings support'
)
source=https://github.com/OpenImageIO/oiio/archive/Release-$pkgver.tar.gz
sha512sums=9565544f20aac2dd0dd9940f9a615899255cf0a6a242a7ece6eeb4f509f60b0f48d3a837da5b758ab31fcec525c59a1950d2c9b7b50d05ba84cda4214c24765e

prepare() {
  cd oiio-Release-$pkgver

  msg 'renaming wrong OS name'
  _OS=$(uname -o)
  [[ $_OS == GNU ]] &&\
    sed -i 's|linux|GNU|i;
           ' src/{cmake/platform.cmake,make/detectplatform.mk}
  [[ $_OS == GNU/Linux ]] &&\
    sed -i 's|[{]uname[}][,]linux]|{uname -o},GNU/Linux|;\|platform| s|linux|GNU/Linux|i
           ' src/{cmake/platform.cmake,make/detectplatform.mk}
  [[ $_OS == GNU/kFreeBSD ]] &&\
    sed -i '\|STREQUAL| s|FreeBSD|kFreeBSD|;\|platform| s|freebsd|GNU/kFreeBSD|i
           ' src/cmake/platform.cmake
    sed -i 's|[{]uname[}][,]linux]|{uname -o},GNU/kFreeBSD|;\|platform| s|linux|GNU/kFreeBSD|i
           ' src/make/detectplatform.mk

  # gif lts
  sed -i 's|gif_lib[.]h|gif_lib-lts.h|
         ' src/gif.imageio/gifinput.cpp

  [[ -d build ]] && rm -r build
  mkdir build
}

build() {
  cd oiio-Release-$pkgver/build
  cmake .. \
      -DCMAKE_INSTALL_PREFIX=/usr\
      -DOIIO_BUILD_TESTS=OFF\
      -DPYLIB_INSTALL_DIR=lib/python2.7/site-packages\
      -DPYLIB_INCLUDE_SONAME=ON\
      -DPYLIB_LIB_PREFIX=OFF\
      -DUSE_EXTERNAL_TBB=OFF
  make
}

package() {
  cd oiio-Release-$pkgver/build
  #cd oiio/build
  make DESTDIR=$pkgdir install
  install -Dm644 ../LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim:set ts=2 sw=2 et: