# Maintainer (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: grizzlyuser <grizzlyuser@protonmail.com>

# parabola changes and rationale
# * removed documentation with embedded non-free fonts

pkgname=openexr
pkgver=2.5.5
pkgrel=1
pkgrel+=.parabola1
pkgdesc="An high dynamic-range image file format library"
pkgdesc+=", without embedded nonfree fonts in the documentation"
url="https://www.openexr.com/"
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('BSD3')
depends=('zlib')
makedepends=('cmake' 'python' 'boost' 'freeglut' 'python-numpy' 'chrpath')
optdepends=('boost-libs: python support' 'python: python support') 
optdepends+=('libreoffice-still: for reading documentation')
conflicts=('ilmbase')
replaces=('ilmbase')
source=($pkgname-$pkgver.tar.gz::"https://github.com/openexr/openexr/archive/v$pkgver.tar.gz")
source+=(install-odt-docs-not-pdf.patch)
sha256sums=('59e98361cb31456a9634378d0f653a2b9554b8900f233450f2396ff495ea76b3')
sha256sums+=('fd0cc640265605b6a25db3dd901641be3adebfa2b748e6b559cffcba1e5ceb94')

prepare() {
  cd $pkgname-$pkgver

  # remove documentation with embedded non-free fonts
  find . -name *.pdf -exec rm -v '{}' \;
  patch -p1 < "$srcdir"/install-odt-docs-not-pdf.patch
}

build() {
  cmake -B build -S $pkgname-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr
  cmake --build build
}

package() {
  DESTDIR="${pkgdir}" cmake --install build
  install -D -m644 $pkgname-$pkgver/LICENSE.md -t "${pkgdir}/usr/share/licenses/${pkgname}"

# Install missing python module
  _pythonpath=`python -c "from sysconfig import get_path; print(get_path('platlib'))"`
  install -Dm755 build/python3*/imathnumpy.so -t "$pkgdir"/$_pythonpath 
}