# $Id: PKGBUILD 287727 2017-01-29 17:55:00Z arojas $
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgbase=opencv
pkgname=opencv
pkgver=3.4.3
pkgrel=2.parabola1
pkgdesc="Free Computer Vision Library, without nonfree SIFT and SURF algorithms, nonfree Milky icons and lena images"
arch=(i686 x86_64 armv7h)
license=(BSD)
url="http://opencv.org/"
depends=(intel-tbb openexr gst-plugins-base libdc1394 cblas lapack libgphoto2 jasper)
makedepends=(cmake python-numpy python2-numpy mesa eigen hdf5 lapacke gtk3)
optdepends=('opencv-samples: samples'
            'gtk3: for the HighGUI module'
            'hdf5: support for HDF5 format'
            'opencl-icd-loader: For coding with OpenCL'
            'python-numpy: Python 3 interface'
            'python2-numpy: Python 2 interface')
mksource=("$pkgbase-$pkgver.zip::https://github.com/opencv/opencv/archive/$pkgver.zip"
          "opencv_contrib-$pkgver.tar.gz::https://github.com/opencv/opencv_contrib/archive/$pkgver.tar.gz")
source=("https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.zip")
mksha256sums=('37c7d8c3b9807902ad11b9181bbde61dcb3898a78a563130494752f46fe8cc5f'
              '6dfb51326f3dfeb659128df952edecd45683626a965aa4a8e1e9c970c40fb636')
sha256sums=('310956f831a6596a69211507cb0989fb814e96a1a235abc0b54603b5e05a6d49')

mksource() {
  cd "$srcdir/opencv_contrib-$pkgver"

  # remove nonfree SIFT and SURF algorithms that are patented in some countries and have some other limitations on the use
  rm -v modules/xfeatures2d/src/{sift,surf}.cpp

  cd "$srcdir/$pkgname-$pkgver"

  # remove nonfree Milky icons
  rm -rv modules/highgui/src/files_Qt/Milky

  # remove nonfree lena.png and lena.jpg images
  rm -v $(find . -iname '*lena*')
}

prepare() {
  cd "$srcdir/opencv_contrib-$pkgver"

  # remove nonfree SIFT and SURF references
  rm -rv modules/xfeatures2d

  mkdir -p ../build
}

build() {
  cd build

  # SSE only available from Pentium 3 onwards (i686 is way older)
  # SSE only available x86 hardware and ARM uses NEON
  case "$CARCH" in
    i686) extra='-DCPU_BASELINE_DISABLE=SSE,SSE2' ;;
    x86_64) extra='-DCPU_BASELINE_DISABLE=SSE3 -DCPU_BASELINE_REQUIRE=SSE2' ;;
    *) extra='' ;;
  esac

  # cmake's FindLAPACK doesn't add cblas to LAPACK_LIBRARIES, so we need to specify them manually
  cmake ../$pkgname-$pkgver \
    -DWITH_OPENCL=ON \
    -DWITH_OPENGL=ON \
    -DWITH_TBB=ON \
    -DOpenGL_GL_PREFERENCE=GLVND \
    -DBUILD_WITH_DEBUG_INFO=OFF \
    -DBUILD_TESTS=OFF \
    -DBUILD_PERF_TESTS=OFF \
    -DBUILD_EXAMPLES=ON \
    -DINSTALL_C_EXAMPLES=ON \
    -DINSTALL_PYTHON_EXAMPLES=ON \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    $extra \
    -DOPENCV_EXTRA_MODULES_PATH="$srcdir/opencv_contrib-$pkgver/modules" \
    -DLAPACK_LIBRARIES="/usr/lib/liblapack.so;/usr/lib/libblas.so;/usr/lib/libcblas.so" \
    -DLAPACK_CBLAS_H="/usr/include/cblas.h" \
    -DLAPACK_LAPACKE_H="/usr/include/lapacke.h"
#    -DWITH_IPP=OFF
  make
}

package_opencv() {
  options=(staticlibs)

  cd build
  make DESTDIR="$pkgdir" install

  # install license file
  install -Dm644 "$srcdir"/$pkgname-$pkgver/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname

  cd "$pkgdir"/usr/share

  # separate samples package
  rm -r OpenCV/samples
  mv OpenCV $pkgname # otherwise folder naming is inconsistent
}

# vim:set ts=2 sw=2 et: