# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=okular
pkgver=19.12.3
pkgrel=3
pkgrel+=.parabola1
pkgdesc='Document Viewer'
pkgdesc+=', with copy-protection anti-feature turned off by default and without nonfree unrar recommendation'
arch=(x86_64)
arch+=(i686 armv7h)
url="https://kde.org/applications/graphics/okular/"
license=(GPL LGPL FDL)
groups=(kde-applications kdegraphics)
depends=(djvulibre libspectre libkexiv2 poppler-qt5 qca kpty kactivities threadweaver kjs kparts purpose discount phonon-qt5)
makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools khtml chmlib)
optdepends=('ebook-tools: mobi and epub support'
            'kdegraphics-mobipocket: mobi support' 'libzip: CHM support'
            'khtml: CHM support' 'chmlib: CHM support' 'calligra: ODT and ODP support'
            'unarchiver: Comic Book Archive support')
source=("https://download.kde.org/stable/release-service/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
         CVE-2020-9359.patch::"https://invent.kde.org/kde/okular/-/commit/6a93a033.patch")
source+=('libre.patch')
sha256sums=('c5de22cc4292e3b7adae3f6ef6566dcba33a1dd5995fb0b968ea3e705a4c04e0'
            'SKIP'
            '58ab539871a68e36de81c80bcd0258a755b64e1cc210430ba60a0e8d5fb51a44'
            '83cf760b3ae6e03d49e02369375dae3ecc05a6800d512dd9ffeaac1648c19457')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>
options=(!zipman)

prepare() {
  mkdir -p build

  patch -d $pkgname-$pkgver -p1 -i "$srcdir"/CVE-2020-9359.patch

  cd $pkgname-$pkgver
  patch -Np1 -i "$srcdir"/libre.patch
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DBUILD_OKULARKIRIGAMI=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}