# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

pkgname=okular

pkgver=17.12.0
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)

pkgdesc="Document Viewer, with copy-protection anti-feature turn off by default"
url="https://kde.org/applications/graphics/okular/"
license=(GPL LGPL FDL)

makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools khtml python chmlib)
depends=(djvulibre libspectre libkexiv2 poppler-qt5 qca-qt5 kpty kactivities threadweaver kjs kparts mesa)
optdepends=('ebook-tools: mobi and epub support'
            'kdegraphics-mobipocket: mobi support'
            'kirigami2: mobile UI'
            'khtml: CHM support'
            'chmlib: CHM support'
            'calligra: ODT and ODP support')
conflicts=(kdegraphics-okular)
replaces=(kdegraphics-okular)
groups=(kde-applications kdegraphics)

source=("https://download.kde.org/stable/applications/$pkgver/src/okular-$pkgver.tar.xz"{,.sig}
        'turn_off_copy-protection_anti-feature.patch')
sha256sums=('0594eb61bd939a596ea5416a682b14ad56120330c3eba11c92b5d72a5b80ff33'
            'SKIP'
            '83cf760b3ae6e03d49e02369375dae3ecc05a6800d512dd9ffeaac1648c19457')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  patch -p1 -i $srcdir/turn_off_copy-protection_anti-feature.patch
}

build() {
  cd build

  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build

  make DESTDIR="$pkgdir" install
}