# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=okular
pkgver=17.04.3
pkgrel=1.parabola1
pkgdesc='Document Viewer, with copy-protection anti-feature turn off by default'
arch=(i686 x86_64 armv7h)
url="https://kde.org/applications/graphics/okular/"
license=(GPL LGPL FDL)
groups=(kde-applications kdegraphics)
depends=(djvulibre libspectre libkexiv2 poppler-qt5 qca-qt5 kpty kactivities threadweaver kjs kparts mesa)
makedepends=(extra-cmake-modules ebook-tools kdegraphics-mobipocket kdoctools khtml python chmlib)
optdepends=('ebook-tools: mobi and epub support'
            'kdegraphics-mobipocket: mobi support'
            'khtml: CHM support'
            'chmlib: CHM support'
            'calligra: ODT and ODP support')
conflicts=(kdegraphics-okular)
replaces=(kdegraphics-okular)
source=("https://download.kde.org/stable/applications/${pkgver}/src/okular-${pkgver}.tar.xz"{,.sig}
        'turn_off_copy-protection_anti-feature.patch')
sha512sums=('36d843f122d7a558cba2236e0db9a4f01af2b167fd24c8e34126bcb4eadadefa97dbe25e2e6168e649e11ad56e9039e22ee45c6c4e38b0f1809266bb9b58be85'
            'SKIP'
            'ff5068947d1d841319d1405c5b21b5ddd90571ffb38e14a18b371e2253afb2588a6700d8e212e3e2a4ec3ad1408bb5333929a98720eb597a4813b2329766a588')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
  cd $pkgname-$pkgver
  patch -p1 -i ../turn_off_copy-protection_anti-feature.patch
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}