# $Id: PKGBUILD 116644 2014-07-31 16:54:09Z jlichtblau $
# Maintainer (Arch): Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor (Arch): Daenyth
# Contributor (Arch): Allan McRae <allan@archlinux.org>
# Contributor (Arch): Vrob (Markus Heuser) mheuser@mi.fu-berlin.de
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=ogmrip
pkgver=1.0.1
pkgrel=1.parabola1
pkgdesc="Libraries and GTK2 interface for DVD ripping using mencoder, without nonfree faac support"
arch=('i686' 'x86_64' 'mips64el')
url="http://ogmrip.sourceforge.net/"
license=('GPL')
depends=('libdvdread>=4.1.3' 'mplayer' 'mencoder' 'enca' 'pkg-config' 'gconf' 'libglade' 'libnotify' 'enchant')
makedepends=('patch' 'intltool' 'perl-xml-parser' 'lame' 'mkvtoolnix' 'libtheora' 'ogmtools' 'gpac' 'vorbis-tools' 'tesseract')
optdepends=('lame: support for the MP3 audio codec'
            'mkvtoolnix: create, alter, and inspect Matroska files'
            'libtheora: decode and encode Ogg Theora files'
            'ogmtools: support for the Ogg Media container'
            'gpac: support for the MP4 container'
            'vorbis-tools: support for the Ogg Vorbis audio codec'
            'gocr: support for the SRT subtitle format'
            'ocrad: support for the SRT subtitle format'
            'tesseract: support for the SRT subtitle format')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
options=('!makeflags')
changelog=$pkgname.changelog
install=$pkgname.install
source=(http://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.gz)
sha256sums=('1c7bb9a346f94a0b6ba783d71df7d21ce021b2f179f5c1a2ebf870366d53ed56')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr --sysconfdir=/usr/share
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install
}