# Maintainer: Márcio Silva <coadde@lavabit.com>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
_pkgflag=libre
pkgver=9.2.0
pkgrel=2
pkgdesc='Mesa 3-D OpenCL library'
url=http://${pkgbase}3d.sourceforge.net
license=(MIT Khronos LGPL)
arch=(mips64el x86_64 i686)
depends=(
  libclc
  $pkgbase
)
optdepends='opencl-headers: headers necessary for OpenCL development'
makedepends=(
  clang
  dri2proto
  glproto
  imake
  libxml2
  python2
)
provides=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
conflicts=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
replaces=($_pkgname-$_pkgflag $_pkgname opencl-nvidia opencl-nvidia-304xx)
options=(!libtool)
source=ftp://ftp.freedesktop.org/pub/$pkgbase/${pkgver%.0}/${pkgbase^}Lib-$pkgver.tar.bz2
sha512sums=26c4b41b7e1d5284b87e2997a14424c1ee0713e11fd9dd65932987832e43b96986ed5e88c06fad4616fc912ffb8e17a2314b282cbf38a2640d76c39724965910

build() {
  cd $srcdir/${pkgbase^}-$pkgver
  autoreconf -vfi
  ./configure --prefix=/usr\
    --enable-opencl\
    --enable-gallium-llvm\
    --enable-r600-llvm-compiler\
    --with-clang-libdir=/usr/lib\
    --with-llvm-shared-libs\
    --with-gallium-drivers=i915,nouveau,r300,r600,radeonsi,svga,swrast
  make V=0
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver
  make -C src/gallium/targets/opencl DESTDIR=$pkgdir install
  install -vdm755 $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}