# $Id: PKGBUILD 230258 2015-01-29 20:40:17Z andyrtr $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname='mesa-demos'
pkgver=8.2.0
pkgrel=4.parabola1
arch=('i686' 'x86_64' 'mips64el')
pkgdesc="Mesa demos and tools, without nonfree demos"
url="http://mesa3d.sourceforge.net"
license=('custom')
replaces=('mesa-demos-libre')
conflicts=('mesa-demos-libre')
depends=('libgl' 'glew' 'freeglut')
mksource=("ftp://ftp.freedesktop.org/pub/mesa/demos/${pkgver}/mesa-demos-${pkgver}.tar.bz2")
source=("https://repo.parabola.nu/other/mesa-demos-libre/mesa-demos-libre-${pkgver}.tar.bz2"
        'LICENSE'
        'libre.patch')
mksha256sums=('e4bfecb5816ddd4b7b37c1bc876b63f1f7f06fda5879221a9774d0952f90ba92')
sha256sums=('a16f31e0b36de9603339d5aaae3b7cded9f560411ca3309d259a12d6071707ca'
            '7fdc119cf53c8ca65396ea73f6d10af641ba41ea1dd2bd44a824726e01c8b3f2'
            '2c381ed421e734dac877116c82ff9df07a8a38658186bba9e95805d145e8eb56')

mksource() {
  cd mesa-demos-${pkgver}
  # remove nonfree demos (pointblast and spriteblast)
  rm -v src/demos/{pointblast,spriteblast}.c
}

prepare() {
  cd mesa-demos-${pkgver}
  # remove nonfree demos references (pointblast and spriteblast)
  patch -Np1 -i ../libre.patch
}

build() {
  cd mesa-demos-${pkgver}
  ./configure --prefix=/usr \
    --with-system-data-files=/usr/share/mesa-demos
  make
}

package() {
  cd mesa-demos-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/mesa-demos"
  install -m755 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-demos/"
}