# $Id: PKGBUILD 178740 2013-02-26 16:15:13Z andyrtr $
# Maintainer: Jan de Groot <jgc@archlinux.org>
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

pkgname='mesa-demos-libre'
pkgver=8.1.0
pkgrel=1
arch=('i686' 'x86_64' 'mips64el')
pkgdesc="Mesa demos and tools, without nonfree demos"
url="http://mesa3d.sourceforge.net"
license=('custom')
depends=('libgl' 'glew')
provides=("mesa-demos=$pkgver")
replaces=('mesa-demos')
conflicts=('mesa-demos')
mksource=("ftp://ftp.freedesktop.org/pub/mesa/demos/${pkgver}/mesa-demos-${pkgver}.tar.bz2"
          'mesa-demos-libre.patch')
source=("https://repo.parabolagnulinux.org/other/mesa-demos-libre/mesa-demos-libre-${pkgver}.tar.bz2"
        'LICENSE')
mksha256sums=('9703fa0646b32a1e68d2abf5628f936f77bf97c69ffcaac90de380820a87a828'
              '476f58fc62e9074936643b0d61165c5160a6d5aed082e60c10b39d219f56913f')
sha256sums=('d2678138f7ff4a684a6d851f1086fd7baf4ee321ef65531063b072632c2c504b'
            '476f58fc62e9074936643b0d61165c5160a6d5aed082e60c10b39d219f56913f')

mksource() {
  cd "${srcdir}/mesa-demos-${pkgver}"

  # Remove nonfree demos (pointblast and spriteblast)
  rm -v src/demos/{pointblast,spriteblast}.c
  patch -Np1 -i "${srcdir}/mesa-demos-libre.patch"
}

build() {
  cd "${srcdir}/mesa-demos-${pkgver}"

  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/mesa-demos-${pkgver}"
  make DESTDIR="${pkgdir}" install
  install -m755 -d "${pkgdir}/usr/share/licenses/mesa-demos"
  install -m755 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/mesa-demos/"
}