# $Id: PKGBUILD 120399 2014-10-08 15:28:25Z anatolik $
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer (Arch): schuay <jakob.gruber@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=mc
pkgver=4.8.13
pkgrel=1.parabola1
pkgdesc="Midnight Commander is a text based filemanager/shell that emulates Norton Commander, with arj recommendation included and nonfree unace and unrar support removed"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.ibiblio.org/mc/"
license=('GPL')
depends=(
    'e2fsprogs'
    'glib2'
    'gpm'
    'libssh2'
    'slang')
makedepends=('libxt' 'libx11')
optdepends=(
    'cabextract: ucab extfs'
    'cdparanoia: audio extfs'
    'cdrkit: iso9660 extfs'
    'gawk: hp48+ extfs'
    'aspell: spelling corrections'
    'cvs: CVS support'
    'mtools: a+ extfs'
    'perl: needed by several extfs scripts'
    'python2-boto: s3+ extfs'
    'python2-pytz: s3+ extfs'
    'smb: VFS support'
    'arj: uarj extfs'
    'zip: uzip extfs'
    'p7zip: support for 7zip archives')
conflicts=('mc-libre')
replaces=('mc-libre')
options=('!emptydirs' '!makeflags')
backup=('etc/mc/edit.indent.rc'
        'etc/mc/filehighlight.ini'
        'etc/mc/mcedit.menu'
        'etc/mc/mc.ext'
        'etc/mc/mc.keymap'
        'etc/mc/mc.menu'
        'etc/mc/sfs.ini')
source=("http://www.midnight-commander.org/downloads/${pkgname}-${pkgver}.tar.bz2"
        'libre.patch')

prepare() {
    cd "${srcdir}/${pkgname}-${pkgver}"

    patch -Np1 -i ../libre.patch
    rm -v src/vfs/extfs/helpers/u{ace,rar}.in
}


build() {
    cd "${srcdir}/${pkgname}-${pkgver}"

    ./configure --prefix=/usr --sysconfdir=/etc --enable-vfs-smb \
        --with-x --libexecdir=/usr/lib

    make
}

package() {
    cd "${srcdir}/${pkgname}-${pkgver}"

    make DESTDIR="${pkgdir}" install

    # Fix FS#15177
    sed 's|op_has_zipinfo = 0|op_has_zipinfo = 1|' \
        -i "${pkgdir}/usr/lib/mc/extfs.d/uzip"

    sed 's#/usr/bin/env python#/usr/bin/python2#' \
        -i "${pkgdir}/usr/lib/mc/extfs.d/s3+"
}

md5sums=('12a521a50da6a86852177591b9623d5e'
         'f91103718b1497ce611b9a12f05e1cc9')