# $Id: PKGBUILD 133054 2015-05-09 12:38:26Z stativ $
# Maintainer (Arch): Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor (Arch): flixie <69one@gmx.net>
# Contributor (Arch): Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=luxrender
pkgver=1.4
_pkgver=dfd211d6faa0
pkgrel=6.parabola1
pkgdesc="Rendering system for physically correct, unbiased image synthesis, with opencl-mesa recommendation"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.luxrender.net/"
license=('GPL')
depends=('boost-libs' 'freeimage' 'openexr' 'openimageio' 'libpng' 'libcl' 'libgl' 'fftw')
optdepends=('blender-addon-luxrender: Blender exporter' 'qt4: Qt GUI'
            'python: pylux Python interface'
            'opencl-mesa: OpenCL support for AMD/ATI GPUs')
makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=$pkgver" 'python' 'opencl-headers')
conflicts=("$pkgname-libre" "$pkgname-parabola")
replaces=("$pkgname-libre" "$pkgname-parabola")
source=(https://bitbucket.org/luxrender/lux/get/${_pkgver}.tar.bz2 \
        force_python3.diff)
md5sums=('7591ac4e86d0232245af38f6cf932c02'
         '42692e65eabc5828693e2682e94b7c64')

prepare() {
  cd "$srcdir"/luxrender-lux-$_pkgver

  patch -Np1 < "$srcdir/force_python3.diff" || true
}

build() {
  cd "$srcdir"/luxrender-lux-$_pkgver


  cmake -DCMAKE_INSTALL_PREFIX=/usr \
    -DLUXRAYS_DISABLE_OPENCL=OFF \
    -DPYTHON_CUSTOM=ON \
    -DPYTHON_LIBRARIES=/usr/lib/libpython3.4m.so \
    -DPYTHON_INCLUDE_PATH=/usr/include/python3.4m/ \
    -DCMAKE_EXE_LINKER_FLAGS=-lpthread \
    .
  make
}

package() {
  cd "$srcdir"/luxrender-lux-$_pkgver
  make DESTDIR="$pkgdir" install

  # fix library path on x86_64
  [ "$CARCH" = "x86_64" ] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib

  #install pylux
  install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.4/pylux.so
}

# vim:set ts=2 sw=2 et: