# $Id$
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Contributor: flixie <69one@gmx.net>
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>
_pkgname=luxrender
pkgname=$_pkgname-libre
pkgver=1.2.1
_pkgver=3066b2161439
pkgrel=5
pkgdesc="Rendering system for physically correct, unbiased image synthesis, without nonfree OpenCL recommendation"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.$_pkgname.net/"
license=('GPL')
depends=('boost-libs' 'freeimage' 'openexr' 'libcl-libre' 'mesa-libgl')
optdepends=('blender-addon-luxrender: Blender for renderer and exporter' 'qt4: Qt GUI' \
            'python: Python interface (pylux)')
makedepends=('cmake' 'boost' 'mesa' 'qt4' "luxrays=$pkgver" 'python' 'opencl-headers')
makedepends+=('gcc-lts')
provides=($_pkgname=$pkgver)
conflicts=$_pkgname
replaces=$_pkgname
source=(https://bitbucket.org/$_pkgname/lux/get/$_pkgver.tar.bz2
        boost-1.53-shared_array_constructor.diff)
md5sums=(
  '87958798c164ad14f92fb4af2595d332'
  'dd19c7ac2ba8c9b703018a176ef77f98')

prepare() {
  cd "$srcdir"/$_pkgname-lux-$_pkgver

  # fix the installation
  sed -i '/.*wxgui.*/ d
          s|-ftree-vectorize ||
         ' CMakeLists.txt
  # fix for boost 1.53
  patch -Np1 < "$srcdir/boost-1.53-shared_array_constructor.diff" || true

  export CXXFLAGS="$CXXFLAGS -lpthread"
}

build() {
  cd "$srcdir"/$_pkgname-lux-$_pkgver

  cmake . -DCMAKE_INSTALL_PREFIX=/usr \
    -DLUXRAYS_DISABLE_OPENCL=OFF \
    -DPYTHON_CUSTOM=ON \
    -DPYTHON_LIBRARIES=/usr/lib/libpython3.3m.so \
    -DPYTHON_INCLUDE_PATH=/usr/include/python3.3m
  make
}

package() {
  cd "$srcdir"/$_pkgname-lux-$_pkgver
  setarch $CARCH make DESTDIR="$pkgdir" install

  # fix library path on 64bit
  [[ $CARCH == x86_64 ]] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib

  #install pylux
  install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.3/pylux.so
}

# vim:set ts=2 sw=2 et: