# $Id: PKGBUILD 163018 2016-02-21 13:02:06Z stativ $
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Maintainer: Márcio Silva <coadde@parabola.nu>
pkgname=luxmark
pkgver=3.1
_scenever=3.1beta3
_pkgver=21d445746802
pkgrel=1.parabola1
pkgdesc="OpenCL benchmark tool, with opencl-mesa recommendation"
arch=('x86_64') # because of embree only x86_64 is supported
url="http://www.luxrender.net/"
license=('GPL3')
depends=('boost-libs' 'embree' 'freetype2' 'freeglut' 'glew' 'libcl' 'libgl' 'libpng' 'openimageio' 'qt4')
makedepends=('cmake' 'boost' 'luxrays' 'mesa' 'opencl-headers' 'freeglut')
optdepends=('opencl-mesa: OpenCL support for AMD/ATI GPUs')
source=($pkgname-$pkgver.tar.bz2::https://bitbucket.org/luxrender/luxmark/get/${_pkgver}.tar.bz2 \
        https://bitbucket.org/luxrender/luxmark/downloads/scenes-v${_scenever}.zip \
        system_scenes.diff)
md5sums=('3b0232ee8a6b170927a77be6c0beef46'
         '03d3d117dfd2f3a7f825e3ea7b68f045'
         'c4a378c08f105a84ef2f792370082cd6')

prepare() {
  cd "$srcdir"/luxrender-luxmark-$_pkgver

  patch -Np1 < "$srcdir/system_scenes.diff"
}

build() {
  cd "$srcdir/luxrender-luxmark-$_pkgver"

  cmake -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    .
  make
}

package() {
  cd "$srcdir/luxrender-luxmark-$_pkgver"
  install -D -m755 bin/luxmark "$pkgdir"/usr/bin/luxmark

  install -d "$pkgdir/usr/share/luxmark"
  cp -a "$srcdir/scenes" "$pkgdir/usr/share/luxmark"
}

# vim:set ts=2 sw=2 et: