# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=linux-libre-firmware
pkgver=1.2.1
pkgrel=1
epoch=1
pkgdesc='Firmware files for Linux-libre'
arch=('any')
url='https://jxself.org/firmware'
license=('GPL3' 'GPL2')
makedepends=('cmake' 'arm-linux-gnueabi-gcc' 'sh-elf-gcc' 'sh-elf-newlib' 'xtensa-elf-gcc')
provides=('linux-firmware')
conflicts=('linux-firmware'
           'linux-firmware-git'
           'kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw'
           'amd-ucode'
           'openfwwf'
           'ath9k-htc-firmware')
replaces=(${conflicts[@]})
options=(!strip)
source=("$url/$pkgname-$pkgver.tar.lz"{,.asc} 'remove-external-toolchains.patch')
sha512sums=('dc4f2e931b4dde217f2e3430e7a0c1a5f42f0844087bf9a771c7e40dbdd8050205d7a80495bd130f87a02a823db7514241d68bfded19548132b3620d4c7e630a'
            'SKIP'
            '19732ee8e8320a143fee462ae79ca4551672bebc425e71dffd0a8d01fb7a7a02c822966c57072becfff5da11e2a6abe4a0f6de93e9c218bba0b594421a541150')
validpgpkeys=('F611A908FFA165C699584ED49D0DB31B545A3198') # Jason Self

prepare() {
  cd $srcdir/$pkgname-$pkgver/src

  # do not download toolchains so we can build offline
  patch -p1 -i $srcdir/remove-external-toolchains.patch
}  

build() {
  cd $srcdir/$pkgname-$pkgver/src
  make
}

package() {
  cd $srcdir/$pkgname-$pkgver/src

  install -dm755 $pkgdir/usr/lib/firmware
  make prefix=$pkgdir/usr/lib/firmware install

  install -Dm644 WHENCE $pkgdir/usr/share/licenses/$pkgname/WHENCE
}