# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=linux-libre-firmware
_commit=e200e491e3f8ebaa38e4ebbc136ef57af5394569 # master
pkgver=20180112.e200e49
pkgrel=1
pkgdesc='Firmware files for Linux-libre'
makedepends=('git' 'gmp')
arch=('any')
url="https://jxself.org/git/?p=linux-libre-firmware.git;a=summary"
license=('GPL2' 'GPL3')
depends=('ath9k-htc-firmware' 'openfwwf')
provides=('linux-firmware')
conflicts=('linux-firmware'
           'linux-firmware-git'
           'kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw'
           'amd-ucode')
replaces=('linux-firmware'
          'linux-firmware-git'
          'kernel26-firmware'
          'ar9170-fw'
          'iwlwifi-1000-ucode'
          'iwlwifi-3945-ucode'
          'iwlwifi-4965-ucode'
          'iwlwifi-5000-ucode'
          'iwlwifi-5150-ucode'
          'iwlwifi-6000-ucode'
          'rt2870usb-fw'
          'rt2x00-rt61-fw'
          'rt2x00-rt71w-fw'
          'amd-ucode')
options=(!strip)
source=("git+https://jxself.org/git/linux-libre-firmware.git#commit=${_commit}")
sha256sums=('SKIP')

prepare() {
  cd "${srcdir}/${pkgname}"
}

pkgver() {
  cd "${srcdir}/${pkgname}"

  # Commit date + short rev
  echo $(TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD).$(git rev-parse --short HEAD)
}

build() {
  cd "${srcdir}/${pkgname}"
  make cis dsp56k isci keyspan_pda #av7110 carl9170fw usbdux
}

package() {
  cd "${srcdir}/${pkgname}"

  make prefix="${pkgdir}"/usr/lib/firmware install

  install -d "${pkgdir}/usr/share/licenses/${pkgname}"
  install -Dm644 WHENCE "${pkgdir}/usr/share/licenses/${pkgname}/"
}