# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=linux-libre-firmware
pkgver=1.1
pkgrel=1
epoch=1
pkgdesc='Firmware files for Linux-libre'
arch=('any')
url='https://jxself.org/firmware'
license=('GPL3' 'GPL2' 'MPL' 'BSD3')
depends=('ath9k-htc-firmware')
makedepends=('cmake' 'gmp' 'gperf' 'arm-linux-gnueabi-gcc')
provides=('linux-firmware')
conflicts=('linux-firmware'
           'linux-firmware-git'
           'kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw'
           'amd-ucode'
           'openfwwf')
replaces=(${conflicts[@]})
source=("${url}/${pkgname}-${pkgver}.tar.lz"{,.asc}
        'remove-wget.patch'
        'config' # carl9170fw configuration
)
sha512sums=('4ef111f86e8a87bab31e02be171e09f47d71884f1737f5329e9dd07e9f799436d8ff2de5aa0b2cfb4bc921ed02bb2b59b9a1ea69176dcef5f902364d8725e75a'
            'SKIP'
            'b6579a0de9e66dcbeec350172764ebedc06a6056fc3592a040f6447d1806f29d82b8bdc36e33b6012aae2068dc6975e70e0c0d1381c84937317bc763c6f2290f'
            '087371c69a8ba394822efa1a41f45ec8f2a7800bcfa63a9e0e492eceaa75b85b6ea5a534e7a37091199d72229c12fe44dc0ad34625ff1c4a09c3725bc09331a3')
validpgpkeys=('F611A908FFA165C699584ED49D0DB31B545A3198') # Jason Self

prepare() {
  cd $srcdir/$pkgname-$pkgver
  
  # Some firmwares download compilers with wget. We don't want that
  patch -p1 -i ../remove-wget.patch

  # Although we still don't use carl9170fw yet, this is a step forward
  cp ../config src/carl9170fw/.config
  sed '13s|config/conf|config/conf --config|' -i src/carl9170fw/autogen.sh
}  

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  make cis isci keyspan_pda openfwwf av7110 dsp56k # usbdux carl9170fw ath9k_htc
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"

  install -dm755 $pkgdir/usr/lib/firmware
  make prefix=$pkgdir/usr/lib/firmware install

  install -Dm644 WHENCE $pkgdir/usr/share/licenses/$pkgname/WHENCE
}