# Maintainer: David P. <megver83@parabola.nu>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

pkgname=linux-libre-firmware
pkgver=1.3
pkgrel=2
epoch=1
pkgdesc='Firmware files for Linux-libre'
arch=('any')
url='https://jxself.org/firmware'
license=('GPL3' 'GPL2')
makedepends=('arm-linux-gnueabi-gcc' 'arm-none-eabi-gcc' 'cmake' 'sh-elf-gcc' 'sh-elf-newlib' 'xtensa-elf-gcc')
provides=('linux-firmware')
conflicts=('linux-firmware'
           'linux-firmware-git'
           'kernel26-firmware'
           'ar9170-fw'
           'iwlwifi-1000-ucode'
           'iwlwifi-3945-ucode'
           'iwlwifi-4965-ucode'
           'iwlwifi-5000-ucode'
           'iwlwifi-5150-ucode'
           'iwlwifi-6000-ucode'
           'rt2870usb-fw'
           'rt2x00-rt61-fw'
           'rt2x00-rt71w-fw'
           'amd-ucode'
           'openfwwf'
           'ath9k-htc-firmware')
replaces=(${conflicts[@]})
options=(!buildflags !makeflags)
source=("$url/$pkgname-$pkgver.tar.lz"{,.asc} 'remove-external-toolchains.patch')
sha512sums=('d3ead6924e686d0212c5993386fdf7ed1d2f68cb899517510ef488b2006a7bb9c1a8e511d23622e0342bdc70410c90291aad60adb2ac5db20c00b40a11508700'
            'SKIP'
            '028f18ab966bd6294034573fce4a8bb9be502ee31f28578803948847a824f5c477d59f21e3a99a8491df7ee24895631f110fd895125e319a875145eec55514fd')
validpgpkeys=('F611A908FFA165C699584ED49D0DB31B545A3198') # Jason Self

prepare() {
  cd $srcdir/$pkgname-$pkgver

  # do not download toolchains so we can build offline
  patch -p0 -i ../remove-external-toolchains.patch
}  

build() {
  cd $srcdir/$pkgname-$pkgver
  make -C src
}

package() {
  cd $srcdir/$pkgname-$pkgver

  install -dm755 $pkgdir/usr/lib/firmware
  make -C src prefix=$pkgdir/usr/lib/firmware install

  install -Dm644 src/WHENCE $pkgdir/usr/share/licenses/$pkgname/WHENCE
}