# $Id: PKGBUILD 220652 2014-08-26 01:15:15Z eric $
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# Contributor: bitlord
# Contributor: André Silva <emulatorman@parabola.nu>

pkgname=liferea
pkgver=1.10.11
pkgrel=1.parabola1
pkgdesc="A desktop news aggregator for online news feeds and weblogs, without nonfree suggestions"
arch=('i686' 'x86_64' 'mips64el')
url="http://liferea.sourceforge.net/"
replaces=('liferea-libre')
conflicts=('liferea-libre')
license=('GPL')
depends=('webkitgtk' 'libnotify' 'json-glib' 'libpeas' 'python2-gobject' 
         'gnome-icon-theme' 'desktop-file-utils')
makedepends=('intltool')
optdepends=('gnome-keyring: for keyring plugin support'
            'libgnome-keyring: for keyring plugin support'
	    'gst-plugins-base: for media player plugin support'
	    'gst-plugins-good: for media player plugin support'
	    'gst-plugins-bad: for media player plugin support')
options=('!emptydirs')
install=liferea.install
source=(https://github.com/lwindolf/liferea/releases/download/v${pkgver}/liferea-${pkgver}.tar.bz2
        remove-non-free-suggestions.patch)
sha1sums=('7ff8197989f4caad5f50c6b4c18ee19699ecf70c'
          '855de60c91b5fee71c7ec88dd04b7d24a02dc0d1')

build() {
  cd liferea-${pkgver}
  # remove nonfree suggestions
  patch -Np1 -i "$srcdir/remove-non-free-suggestions.patch"
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --disable-schemas-compile
  make
}

package() {
  cd liferea-${pkgver}
  make DESTDIR="${pkgdir}" install
}