# Maintainer: Joshua Haase <hahj87@gmail.com
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@lavabit.com>

pkgbase=libretools
pkgname=(libretools libretools-mips64el librelib gitget)
pkgdesc="Programs for Parabola development"
url="https://projects.parabolagnulinux.org/packages/libretools.git/"
license=('GPL3' 'GPL2')

pkgver=20140106
_libretools_commit=7f3842777aeed4bd7b7ec28ef59c56c489a0831f
_devtools_commit=534d2015b45e013b37e1edbb997bd4df27d7b8fd

_packages_url=https://projects.parabolagnulinux.org/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
	$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)

pkgrel=1
arch=('any')
makedepends=(emacs ronn) # emacs --batch is used during the build to process text
checkdepends=(sh-roundup)

build() {
  cd "$srcdir"
  ln -sf devtools-par-$_devtools_commit devtools-par
  cd "$srcdir/$pkgbase-$_libretools_commit"
  make build-libretools build-libretools-mips64el build-librelib build-doc
}

check() {
  cd "$srcdir/$pkgbase-$_libretools_commit"

  SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}

package_librelib() {
  pkgdesc="Shell library portion of libretools"
  depends=(
    wget # `aur` and `lib/blacklist.sh`
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-librelib DESTDIR="$pkgdir"
}

package_gitget() {
  depends=("librelib=$pkgver" git)

  provides=("libregit=$pkgver")
  conflicts=("libregit")
  replaces=("libregit")

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-gitget DESTDIR="$pkgdir"
}

package_libretools() {
  backup=(etc/libretools.conf etc/libretools.d/chroot.conf etc/libretools.d/librefetch.conf)
  install=libretools.install
  replaces=(chroottools)
  conflicts=(devtools)

  depends=(
    "librelib=$pkgver"
    "gitget=$pkgver" # `createworkdir`
    arch-install-scripts # `archroot` uses `pacstrap`
    openssh # `librerelease`
    rsync # `librerelease` and `makechrootpkg.sh`
    subversion # `diff-unfree`
    tokyocabinet # `treepkg`
  )
  optdepends=('namcap: to check package files')

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools install-doc DESTDIR="$pkgdir"
}

package_libretools-mips64el() {
  pkgdesc="Scripts for Parabola development (for mips64el architecture)"
  depends=("$pkgbase=$pkgver"
    git # mips-add
  )

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools-mips64el DESTDIR="$pkgdir"
}

md5sums=('bd24a08620fb8dfd298e926250fa28b0'
         'ec69dffa68829f063224de19bbd55fa9')