# $Id: PKGBUILD 182699 2016-07-12 18:48:59Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=libosinfo
pkgver=0.3.1
pkgrel=1.parabola1
pkgdesc="GObject based library API for managing information about operating systems, hypervisors and the (virtual) hardware devices they can support, without support for nonfree systems"
arch=('i686' 'x86_64' 'armv7h')
url="http://libosinfo.org/"
license=('GPL' 'LGPL')
depends=('glib2' 'libxslt')
makedepends=('check' 'gobject-introspection' 'intltool' 'libsoup' 'vala' 'python2')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
options=('!libtool')
source=(https://fedorahosted.org/releases/l/i/$pkgname/$pkgname-$pkgver.tar.gz
        libre.patch)
sha256sums=('50b272943d68b77d5259f72be860acfd048126bc27e7aa9c2f9c77a7eacf3894'
            '5d376a134e9bf240e50618431ac916dbde43e2553e6cfa423e03f83954e3096f')

prepare() {
  cd $pkgname-$pkgver

  rm -rv {data/{datamap/microsoft.com,os,install-script},docs,test/isodata/*}

  patch -Np1 -i ../libre.patch

  cd po
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --enable-udev \
              --with-udev-rulesdir=/usr/lib/udev/rules.d \
              --with-usb-ids-path=/usr/share/hwdata/usb.ids \
              --with-pci-ids-path=/usr/share/hwdata/pci.ids
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}