# $Id: PKGBUILD 159646 2016-01-31 03:46:54Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=libosinfo
pkgver=0.3.0
pkgrel=1.parabola1
pkgdesc="GObject based library API for managing information about operating systems, hypervisors and the (virtual) hardware devices they can support, without support for nonfree systems"
arch=('i686' 'x86_64')
url="http://libosinfo.org/"
license=('GPL' 'LGPL')
depends=('glib2' 'libxslt')
makedepends=('check' 'gobject-introspection' 'intltool' 'libsoup' 'vala' 'python2')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
options=('!libtool')
source=(https://fedorahosted.org/releases/l/i/$pkgname/$pkgname-$pkgver.tar.gz
        libre.patch)
sha256sums=('538a3468792e919edf5364fe102d751353ae600a92ad3a24f024424a182cefbc'
            'a74ec92c664d4eb5856ea30fa081b803390077aa4aced524cea85a71a8e16799')

prepare() {
  cd $pkgname-$pkgver

  rm -rv {data/{datamap/microsoft.com,os,install-script},docs,test/isodata/*}

  patch -Np1 -i ../libre.patch

  cd po
  for file in *.po; do
    intltool-update ${file%.*}
    msgattrib --no-obsolete -o $file $file
  done
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
              --disable-static --enable-udev \
              --with-udev-rulesdir=/usr/lib/udev/rules.d \
              --with-usb-ids-path=/usr/share/hwdata/usb.ids \
              --with-pci-ids-path=/usr/share/hwdata/pci.ids
  make
}

check() {
  cd $pkgname-$pkgver
  make check
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}