# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of libjpeg-turbo

_pkgname=libjpeg-turbo
pkgname=libjpeg-turbo-static
pkgver=1.4.2
pkgrel=2
pkgdesc='JPEG image codec with accelerated baseline compression and decompression (static libraries only)'
url='http://libjpeg-turbo.virtualgl.org/'
arch=('i686' 'x86_64' 'armv7h')
license=('custom')
makedepends=('nasm' 'jdk8-openjdk')
depends=('libjpeg-turbo')
source=("http://downloads.sourceforge.net/project/${_pkgname}/${pkgver}/${_pkgname}-${pkgver}.tar.gz")
sha1sums=('2666158ccd5318513f875867bbc4af52f6eb9f0b')

options=('!makeflags' 'staticlibs')

build() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	export JNI_CFLAGS='-I/usr/lib/jvm/default/include -I/usr/lib/jvm/default/include/linux'
	./configure \
		--prefix=/usr \
		--with-jpeg8 \
		--with-java \

	make
}

check() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	make test
}

package() {
	cd "${srcdir}/${_pkgname}-${pkgver}"
	make \
		DESTDIR="${pkgdir}" \
		install
	
	# remove conflicting files
	rm -vr ${pkgdir}/usr/{bin,include,share}
	rm -v ${pkgdir}/usr/lib/lib*.so*
}