# $Id: PKGBUILD 151867 2012-03-03 15:53:13Z schiv $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor:	Ionut Biru <ibiru@archlinux.org>
# Contributor: Hugo Doria <hugo@archlinux.org>
# Maintainer: Henry Jensen <hjensen@connochaetos.org>
# Contributor (Parabola): André Silva <andre.paulista@adinet.com.uy>

_pkgname=lame
pkgname=lame-libre
pkgver=3.99.5
pkgrel=1
pkgdesc="A high quality MPEG Audio Layer III (MP3) encoder"
arch=('i686' 'x86_64')
url="http://lame.sourceforge.net/"
depends=('ncurses')
makedepends=('nasm')
replaces=('lame')
provides=("lame=${pkgver}")
conflicts=('lame')
license=('LGPL')
options=('!libtool')
source=("http://downloads.sourceforge.net/$_pkgname/$_pkgname-$pkgver.tar.gz")
md5sums=('84835b313d4a8b68f5349816d33e07ce')

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  ./configure --prefix=/usr \
              --enable-nasm \
              --enable-shared
  make
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: