# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux,org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=konqueror

pkgver=17.12.0
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)

pkgdesc="KDE File Manager & Web Browser, without Google, nonfree software recommendation and nonfree qt5-webengine support"
url="https://konqueror.org/"
license=(LGPL)

makedepends=(extra-cmake-modules kdoctools python tidy kdesignerplugin kdesu khtml)
depends=(dolphin keditbookmarks kdelibs4support kinit)
optdepends=('tidy: tidy HTML plugin'
            'kdesu: shell command plugin'
            'khtml: alternative web engine')
conflicts=(kdebase-konqueror kdebase-konq-plugins)
replaces=(kdebase-konqueror kdebase-konq-plugins)
groups=(kde-applications kdebase)

source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'libre.patch')
sha256sums=('5ece6ddafb17dc1e982d230e3a63a3a9ca4b4991848ef3a72c7673f5a691d7a7'
            'SKIP'
            '469f413dbe1fc19bde685a702c5291a68e22880edb51eade012d08d965d0364c')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  # Remove nonfree WebEngine support and nonfree software or Google recommendation
  rm -rv webenginepart
  patch -p1 -i $srcdir/libre.patch
}

build() {
  cd build

  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build

  make DESTDIR="$pkgdir" install
}