# Maintainer (Arch): Antonio Rojas <arojas@archlinux,org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Michał Masłowski <mtjm@mtjm.eu>

pkgname=konqueror
pkgver=16.12.3
pkgrel=2.parabola1
pkgdesc="KDE File Manager & Web Browser, without Google, nonfree software recommendation and nonfree qt5-webengine support"
arch=(i686 x86_64 armv7h)
url="https://konqueror.org/"
license=(LGPL)
depends=(dolphin keditbookmarks opengl-driver)
makedepends=(extra-cmake-modules kdoctools python tidy kdesignerplugin kdesu)
optdepends=('tidy: tidy HTML plugin' 'kdesu: shell command plugin')
conflicts=(kdebase-konqueror kdebase-konq-plugins)
replaces=(kdebase-konqueror kdebase-konq-plugins)
groups=(kde-applications kdebase)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'libre.patch')
sha256sums=('e52654a1bb2c0be317f8ed80dba3147bc4d2126abce209ab57c6e69e64159bdf'
            'SKIP'
            'a7a19439e211cd96f63273c9cf5a8dbfa7385b02e4143e67a0992551c1297a73')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  # Remove nonfree WebEngine support and nonfree software or Google recommendation
  rm -rv webenginepart
  patch -p1 -i ../libre.patch
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}