# $Id$
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

pkgname=kio
pkgver=5.42.0
pkgrel=1.parabola1
pkgdesc='Resource and network access abstraction, without non-privacy search engines'
arch=(x86_64 i686 armv7h)
url='https://community.kde.org/Frameworks'
license=(LGPL)
depends=(solid kjobwidgets kbookmarks libxslt kwallet desktop-file-utils)
makedepends=(extra-cmake-modules kdoctools python doxygen qt5-tools)
optdepends=('kio-extras: extra protocols support (sftp, fish and more)' 'kdoctools: for the help kioslave'
            'knetattach: to add new kio-remote entries')
groups=(kf5)
source=("https://download.kde.org/stable/frameworks/${pkgver%.*}/$pkgname-$pkgver.tar.xz"{,.sig}
        kdebug-352776.patch::"https://cgit.kde.org/kio.git/patch/?id=248941a0"
        "duckduckgo_html.desktop"
        "duckduckgo_lite.desktop")
sha256sums=('ec1d0ef9523661614f347e3c99efe98813d0fab92e8fdb4a995685d013524694'
            'SKIP'
            '27231fbc2018caba19724a03b9ece21215bfb8d37d8cfe4e3b09095b4630f250'
            '31910ab7393e67609f15e04a57f6406f63e6dae58b01bce0787741bc5958f292'
            '40466a9dad7075f2525e9e024720da7d7b49a22892b6fca8b81cc0e6408d2f7d')
validpgpkeys=(53E6B47B45CEA3E0D5B7457758D0EE648A48B3BB) # David Faure <faure@kde.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  patch -p1 -i ../kdebug-352776.patch # Fix file chooser layout with Qt 5.10

  # Removing non-privacy search providers
  rm -v src/urifilters/ikws/searchproviders/{7digital,acronym,amazon{,_mp3},amg,backports,baidu,bing,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,google_shopping,imdb,jamendo,jeeves,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop

  # Adding DuckDuckGo HTML
  cp -v "$srcdir/duckduckgo_html.desktop" src/urifilters/ikws/searchproviders
  # Adding DuckDuckGo Lite
  cp -v "$srcdir/duckduckgo_lite.desktop" src/urifilters/ikws/searchproviders
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_INSTALL_LIBEXECDIR=lib \
    -DBUILD_TESTING=OFF \
    -DBUILD_QCH=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}