# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kio-extras
pkgver=16.12.3
pkgrel=1.parabola1
pkgdesc="Additional components to increase the functionality of KIO, without nonfree qt5-webengine support"
arch=(i686 x86_64)
url='https://www.kde.org/applications/internet/'
license=(LGPL)
depends=(kdelibs4support khtml kdnssd libssh smbclient exiv2 openexr openslp libmtp kpty kactivities)
makedepends=(extra-cmake-modules kdoctools kdesignerplugin)
optdepends=('qt5-imageformats: thumbnails for additional image formats'
            'kimageformats: thumbnails for additional image formats')
groups=(kde-applications kdenetwork)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('5af7b4dac320ed6d0897c8940e6043ef45a4e1d3a4f9f12e8513215633a5d7d5'
            'SKIP')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}