# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

pkgname=kinfocenter

pkgver=5.11.5
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)

pkgdesc="A utility that provides information about a computer system (Parabola rebranded)"
url="https://www.kde.org/applications/system/kinfocenter/"
license=(LGPL)

depends=(kcmutils pciutils glu libraw1394 kwayland)
makedepends=(extra-cmake-modules python plasma-framework kdoctools)
groups=(plasma)

source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig}
        parabola-logo.svg::https://wiki.parabola.nu/images/a/af/Parabolagnu%2Blinuxlibre-dark-scalable.svg
        kcm-about-distrorc)
sha256sums=('2e36ac5817ca8fbba264ae2ba0061b97ae740690525160296ba823328989a77a'
            'SKIP'
            '75136b90185242891cbeb993285f400bcc9c6c70fdccb0f5e50790acaf875b92'
            '9c874f9ee68dc1c46fab1255f28bdca892e664b35208220db77ab59e04617a96')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
              '348C8651206633FD983A8FC4DEACEA00075E1D76'  # KDE Neon
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

prepare() {
  mkdir -p build
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install

  # Install Parabola logo
  install -Dm644 "$srcdir"/parabola-logo.svg "$pkgdir"/usr/share/about-distro/parabola-logo.svg
  install -Dm644 "$srcdir"/kcm-about-distrorc "$pkgdir"/etc/xdg/kcm-about-distrorc
}