# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

pkgname=khotkeys

pkgver=5.11.4
pkgrel=1.parabola1
arch=(i686 x86_64 armv7h)

pkgdesc="KHotKeys, with DuckDuckGo HTML support"
url="https://www.kde.org/workspaces/plasmadesktop/"
license=(LGPL)

depends=(plasma-workspace)
makedepends=(extra-cmake-modules kdoctools python kdesignerplugin)
conflicts=(kdebase-workspace)
groups=(plasma)

source=("https://download.kde.org/stable/plasma/$pkgver/$pkgname-$pkgver.tar.xz"{,.sig})
sha256sums=('8601789ea3b796677c887e7c3c7a2f1d4053474797d8f4f6d7cf50f9d7a15f73'
            'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell
              '348C8651206633FD983A8FC4DEACEA00075E1D76'  # KDE Neon
              'D07BD8662C56CB291B316EB2F5675605C74E02CF') # David Edmundson

prepare() {
  mkdir -p build
  cd $pkgname-$pkgver
  sed -i 's|google[.]com|duckduckgo.com/html|' data/defaults.khotkeys
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}