# $Id: PKGBUILD 172283 2012-12-02 07:47:38Z andrea $
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=kdeutils-ark
pkgname=kdeutils-ark-libre
pkgver=4.9.4
pkgrel=1
pkgdesc='Archiving Tool'
url='http://kde.org/applications/utilities/ark/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdeutils')
depends=('kdebase-runtime' 'kdebase-lib' 'libarchive' 'qjson')
makedepends=('cmake' 'automoc4')
optdepends=('p7zip' 'zip' 'unzip' 'ununrar')
install=${_pkgname}.install
provides=("kdeutils-ark=$pkgver")
replaces=('kdeutils-ark')
conflicts=('kdeutils-ark')
source=("http://download.kde.org/stable/${pkgver}/src/ark-${pkgver}.tar.xz")
sha1sums=('074aece141ec229b5d72b39e4d31af4e5b4550cb')

build() {
  cd "${srcdir}"
  mkdir build
  cd build
  cmake ../ark-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr
  make
}

package() {
  cd $srcdir/build
  make DESTDIR=$pkgdir install
  cd $srcdir/build/doc
  make DESTDIR=$pkgdir install
}