# Maintainer (arch): Antonio Rojas <arojas@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>


# parabola changes and rationale:
# - build without qt5-webengine


pkgname=kdepim-addons
pkgver=18.12.3
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Addons for KDE PIM applications'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://kontact.kde.org'
license=(GPL LGPL FDL)
depends=(incidenceeditor ktnef libksieve akonadi-notes akonadi-import-wizard kparts poppler-qt5 kitinerary discount)
makedepends=(extra-cmake-modules kdoctools boost)
groups=(kde-applications kdepim)
source=("https://download.kde.org/stable/applications/$pkgver/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'libre.patch')
sha256sums=('450a3f257e998e733b69703a1a813abab93c571c602702cbb4d9ab4ac25e8ce5'
            'SKIP'
            'f416c6397a51db17674d891ea6c5b3939e017bc8f1a78fc2856b59fe131e2700')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid@kde.org>
              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build

  cd $pkgname-$pkgver
  patch -p1 -i ../libre.patch
  rm -rv plugins/webengineurlinterceptor
}

build() {
  cd build
  cmake ../$pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}