# $Id: PKGBUILD 288746 2017-02-12 14:20:09Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kdenetwork-kopete
pkgver=16.12.2
pkgrel=2.parabola1
pkgdesc='Instant Messenger, without nonfree Skype support'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdenetwork')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=('kdebase-runtime' 'libotr' 'qimageblitz' 'kdepimlibs4')
makedepends=('cmake' 'automoc4' 'boost' 'mediastreamer' 'libgadu' 'jsoncpp')
optdepends=('mediastreamer: jingle support' 'libgadu: Gadu-Gadu protocol')
source=("http://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz"{,.sig} kopete-mediastreamer2.14.patch
        CVE-2017-5593.patch::"https://cgit.kde.org/kopete.git/patch/?id=6243764c")
sha1sums=('2db7a06b424edeb20571115b6d66f2f639562c56'
          'SKIP'
          'b284ffb226cbcc0da6540ecd978d37287aa6eddb'
          '1ce697b8fe41f86b56d31a16220319e8c1478c52')
validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7) # Albert Astals Cid <aacid@kde.org>

prepare() {
  cd kopete-$pkgver
# Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  rm -rv protocols/skype
  sed 's/, Skype//' -i doc/index.docbook
  cd ..
  mkdir -p build

# Fix build with mediastreamer 2.14
  cd kopete-$pkgver
  patch -p1 -i ../kopete-mediastreamer2.14.patch
# Fix CVE-2017-5593
  patch -p1 -i ../CVE-2017-5593.patch
}

build() {
  cd build
  cmake ../kopete-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DWITH_skype=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}