# $Id: PKGBUILD 233875 2015-03-15 14:51:39Z arojas $
# Maintainer (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kdenetwork-kopete
pkgver=14.12.3
pkgrel=2.parabola1
pkgdesc='Instant Messenger, without nonfree Skype support'
url='http://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'mips64el')
license=('GPL' 'LGPL' 'FDL')
groups=('kde' 'kdenetwork')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=('kdebase-runtime' 'kdepimlibs' 'qca-ossl' 'libotr' 'libidn'
         'qimageblitz' 'libgadu' 'jsoncpp')
makedepends=('cmake' 'automoc4' 'boost' 'kdepim-libkdepim' 'mediastreamer')
optdepends=('mediastreamer: jingle support')
install=${pkgname}.install
source=("http://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz"
        'mediastreamer-2.11.patch')
sha1sums=('7582f0ee8198fa62a5f02c6e532b993258df6fd8'
          '7999bb62c2c228ef1ee9056e4f1b910b8cb02fcf')

prepare() {
  cd kopete-${pkgver}
  # Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  rm -rv protocols/skype
  sed 's/, Skype//' -i doc/index.docbook
  cd ..
  mkdir build

# fix compilation with mediastreamer 2.11
  cd kopete-$pkgver
  patch -p1 -i "$srcdir"/mediastreamer-2.11.patch
}

build() {
  cd build
  cmake ../kopete-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DWITH_skype=OFF
  make
}

package() {
  cd build
  make DESTDIR=$pkgdir install
}