# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=kdenetwork-kopete
pkgver=17.08.0
pkgrel=1.parabola1
pkgdesc='Instant Messenger, without nonfree Skype support'
url='https://kde.org/applications/internet/kopete/'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdenetwork')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
depends=('kdebase-runtime' 'libotr' 'qimageblitz' 'kdepimlibs4' 'qca-qt4')
makedepends=('cmake' 'automoc4' 'boost' 'mediastreamer' 'libgadu' 'jsoncpp' 'openssl')
optdepends=('mediastreamer: jingle support'
	    'libgadu: Gadu-Gadu protocol' 
	    'openssl-1.0: jingle support')
source=("https://download.kde.org/stable/applications/${pkgver}/src/kopete-${pkgver}.tar.xz"{,.sig}
        'kopete-mediastreamer2.14.patch'
	'kopete-pthread-link.patch')
sha512sums=('4d0e0d13ea1980656b2209bab54d49147d58b797edaed207d76af6f83bb2702655ae88f86f7b97f9c7b752e407a422a6fa354efc1eafacc7166df226093db9d5'
            'SKIP'
            '6aac8084becfc619a6746828573242ddd0d901cc4c8fa4feb3477a395605330242e2d8a8636b319b1a5afb91074e07e1dd4dd1a8d7a8cfe332b9783526571e6a'
            '7200c6f580425ef41b27d885ea73301772f75e0a26c829c1741eeb22c084a0f703baea85863522ebf78d55865fe84d725624da6443c6e3174e8a16644a5bf2db')
validpgpkeys=('CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7'  # Albert Astals Cid <aacid@kde.org>
              'F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87') # Christoph Feck <cfeck@kde.org>

prepare() {
  cd kopete-$pkgver
# Based on http://bzr.trisquel.info/package-helpers/trunk/annotate/head%3A/helpers/natty/make-kdenetwork, revision 34.
  rm -rv protocols/skype
  sed 's/, Skype//' -i doc/index.docbook
  cd ..
  mkdir -p build

# Fix build with mediastreamer 2.14
  cd kopete-$pkgver
  patch -p1 -i ../kopete-mediastreamer2.14.patch
# Fix linking to pthread in libjingle-call
  patch -p1 -i ../kopete-pthread-link.patch
# Fix build with OpenSSL 1.1 (based on Fedora patch for libjingle)
#  cd protocols/jabber/libjingle
#  patch -p1 -i "$srcdir"/kopete-openssl-1.1.patch
}

build() {
  cd build
  cmake ../kopete-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_SKIP_RPATH=ON \
    -DWITH_Libmsn=OFF \
    -DOPENSSL_INCLUDE_DIR=/usr/include/openssl-1.0 \
    -DOPENSSL_SSL_LIBRARY=/usr/lib/openssl-1.0/libssl.so \
    -DOPENSSL_CRYPTO_LIBRARY=/usr/lib/openssl-1.0/libcrypto.so \
    -DWITH_skype=OFF
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}