# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=kdelibs
pkgver=4.14.30
_kdeappver=16.12.3
pkgrel=1.parabola1
pkgdesc="KDE Core Libraries, without nonfree plugins recommendation support"
arch=('i686' 'x86_64' 'armv7h')
url='https://www.kde.org/'
license=('GPL' 'LGPL' 'FDL')
replaces=('kdelibs-libre')
conflicts=('kdelibs-libre')
depends=('attica-qt4' 'libxss' 'qca-qt4' 'libdbusmenu-qt4' 'polkit-qt4'
        'shared-mime-info' 'enchant' 'giflib' 'jasper' 'openexr'
        'docbook-xsl' 'upower' 'udisks2' 'libxcursor' 'phonon-qt4'
        'media-player-info' 'libutempter' 'icu')
makedepends=('cmake' 'automoc4' 'avahi' 'libgl' 'mesa')
source=("https://download.kde.org/stable/applications/${_kdeappver}/src/$pkgname-$pkgver.tar.xz"
        'kde-applications-menu.patch' 'khtml-fsdg.diff' 'qt4.patch' 'kdelibs-no-kdewebkit.patch')
sha256sums=('a39fc3ef320c27ea49e5d238b2a860ef61824a20922268a18392b0521a38196d'
            '0eed754cf3e9f41be5ea22314bf49cf5571b421d81b8f525287830bd1b9b684e'
            'fa553130cf5d1d24e4767d4edfb7eeb889dfd9f19a9b4010eeb9051be171a45f'
            'ced10a9a83ff2a7f82edf51f6f399f8338b34ab5a589ef43637517d204843bea'
            '2df372f1bfcef1902349f9ca8820315030d39dd2bb769776b94fd3fcbf9621f5')

prepare() {
  mkdir -p build
  cd ${pkgname}-${pkgver}
  # avoid file conflict with gnome-menus
  patch -p1 -i ../kde-applications-menu.patch
  # don't ask the user to download a plugin, it's probably nonfree
  patch -p1 -i ../khtml-fsdg.diff
  # qmake refers to Qt5
  patch -p1 -i ../qt4.patch
  # disable kdewebkit (Fedora)
  patch -p1 -i ../kdelibs-no-kdewebkit.patch
}

build() {
       cd build
       cmake ../$pkgname-$pkgver \
               -DCMAKE_BUILD_TYPE=Release \
               -DKDE4_BUILD_TESTS=OFF \
               -DCMAKE_SKIP_RPATH=ON \
               -DKDE_DISTRIBUTION_TEXT='Parabola GNU/Linux-libre' \
               -DCMAKE_INSTALL_PREFIX=/usr \
               -DSYSCONF_INSTALL_DIR=/etc \
               -DLOCALE_INSTALL_DIR=/usr/share/locale/kde4 \
               -DKDE_DEFAULT_HOME='.kde4' \
               -DWITH_FAM=OFF \
               -DWITH_SOLID_UDISKS2=ON
       make
}

package() {
       cd build
       make DESTDIR="$pkgdir" install

       # cert bundle seems to be hardcoded
       # link it to the one from ca-certificates
       rm -f "$pkgdir"/usr/share/apps/kssl/ca-bundle.crt
       ln -sf /etc/ssl/certs/ca-certificates.crt "$pkgdir"/usr/share/apps/kssl/ca-bundle.crt
}