# $Id: PKGBUILD 290221 2017-03-09 16:12:45Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>

pkgname=kdelibs
pkgver=4.14.34
_kdeappver=17.04.3
pkgrel=1.parabola1
pkgdesc="KDE Core Libraries, without nonfree plugins recommendation support"
arch=('i686' 'x86_64' 'armv7h')
url='https://www.kde.org/'
license=('GPL' 'LGPL' 'FDL')
replaces=('kdelibs-libre')
conflicts=('kdelibs-libre')
depends=('attica-qt4' 'libxss' 'libdbusmenu-qt4' 'polkit-qt4'
        'shared-mime-info' 'enchant' 'giflib' 'jasper' 'openexr'
        'docbook-xsl' 'upower' 'udisks2' 'libxcursor' 'phonon-qt4'
        'media-player-info' 'libutempter' 'icu')
makedepends=('cmake' 'automoc4' 'avahi' 'libgl' 'mesa')
source=("https://download.kde.org/stable/applications/${_kdeappver}/src/$pkgname-$pkgver.tar.xz"{,.sig}
        'kde-applications-menu.patch'
        'khtml-fsdg.diff'
        'qt4.patch'
        'kdelibs-no-kdewebkit.patch'
        'kdelibs-openssl-1.1.patch')
sha512sums=('57ba1591e6996af79f03e8a3d4d0c278c027ad65c717fcbdb857df68a3df47ddec6b7c34dfd682d590bfa9ed6800974b53ff29aa7ab73522caebc9897cbd81c0'
            'SKIP'
            '01e0d82c2de1dc553b6341758b75b6db9bdfbdd717964e30ddd4453501daaa438623f5a663156a30de1d1f370e02d6db3f2b67b829d268cc71b2a09fd3d469e3'
            'fd3fb14e26bdda8d1e17e2522a3374887137055892e7958b66ed1ec0205c7e0bcd6a0eba3562ab672f2136768a36ac7ab85cc5b90867de6594f9dc3f27b913ef'
            'f87ed43a22ae01aeb37db15fb6408f47ac4f95fdd2df7128729f2d61d79a481d37062d2f75786ed5fe5b2c29a4d33c8ff18273510c112c074f81e44220ed9a16'
            'd4404915a1f27ba0eaf051d1bce5f693a87aba836e1a460d4f31014f6427132c9748591959bbaa2400846377399c2db8fa690fe0776faa33051b82329b53f208'
            'bdaa8f397d2c53d7347061d7aec5ff9f02d62652e3a7846f8affc6327058cdddf288fb53168283988a01088d9fcf147078133cedb7c296af180a66ea3a367948')
validpgpkeys=(F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87) # Christoph Feck <cfeck@kde.org>

prepare() {
  mkdir -p build
  cd ${pkgname}-${pkgver}
  # avoid file conflict with gnome-menus
  patch -p1 -i ../kde-applications-menu.patch
  # don't ask the user to download a plugin, it's probably nonfree
  patch -p1 -i ../khtml-fsdg.diff
  # qmake refers to Qt5
  patch -p1 -i ../qt4.patch
  # disable kdewebkit (Fedora)
  patch -p1 -i ../kdelibs-no-kdewebkit.patch
  # fix build with openSSL 1.1 (OpenMandriva)
  patch -p1 -i ../kdelibs-openssl-1.1.patch
}

build() {
       cd build
       cmake ../$pkgname-$pkgver \
               -DCMAKE_BUILD_TYPE=Release \
               -DKDE4_BUILD_TESTS=OFF \
               -DCMAKE_SKIP_RPATH=ON \
               -DKDE_DISTRIBUTION_TEXT='Parabola GNU/Linux-libre' \
               -DCMAKE_INSTALL_PREFIX=/usr \
               -DSYSCONF_INSTALL_DIR=/etc \
               -DLOCALE_INSTALL_DIR=/usr/share/locale/kde4 \
               -DKDE_DEFAULT_HOME='.kde4' \
               -DWITH_FAM=OFF \
               -DWITH_SOLID_UDISKS2=ON
       make
}

package() {
       cd build
       make DESTDIR="$pkgdir" install

       # cert bundle seems to be hardcoded
       # link it to the one from ca-certificates
       rm -f "$pkgdir"/usr/share/apps/kssl/ca-bundle.crt
       ln -sf /etc/ssl/certs/ca-certificates.crt "$pkgdir"/usr/share/apps/kssl/ca-bundle.crt
}