# $Id$
# Maintainer: Andrea Scarpino <andrea@archlinux.org>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=kdebase-runtime
pkgname=kdebase-runtime-libre
pkgver=4.9.5
pkgrel=1
pkgdesc="Plugins and applications necessary for the running of KDE applications (without non-privacy search providers)"
arch=('i686' 'x86_64' 'mips64el')
url='https://projects.kde.org/projects/kde/kde-runtime'
license=('GPL' 'LGPL')
depends=('nepomuk-core' 'smbclient' 'libssh' 'libcanberra' 'oxygen-icons' 'xorg-xauth'
         'kactivities')
makedepends=('pkg-config' 'cmake' 'automoc4' 'kdepimlibs' 'openslp' 'doxygen'
             'networkmanager')
optdepends=('kdepimlibs: to generate drkonqi reports'
            'htdig: to build the search index in khelpcenter'
            'rarian: needed by khelpcenter'
            'gdb: drkonq crash handler')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
install="${_pkgname}.install"
source=("http://download.kde.org/stable/${pkgver}/src/kde-runtime-${pkgver}.tar.xz"
        'duckduckgo_html.desktop'
        'duckduckgo_lite.desktop')
sha1sums=('6e2abeb8cc2d40d248dfabd49da264ac375fe6b5'
          'aa6f39f4b0ad3c110fd05cd6c41190afae9773dd'
          'ac3bac94a2c4b1444642524bc5fb539c4c5dcc5b')

build() {
    cd "${srcdir}"

# Removing non-privacy search providers 
    rm -v kde-runtime-${pkgver}/kurifilter-plugins/ikws/searchproviders/{7digital,acronym,altavista,amazon{,_mp3},amg,austronaut,backports,baidu,bing,blip,cia,dbug,deb,duckduckgo{,_info,_shopping},facebook,ecosia,feedster,flickr,flickrcc,froogle,google,google_advanced,google_code,google_groups,google_images,google_lucky,google_maps,google_movie,google_news,gracenote,imdb,jeeves,katatudo,magnatune,metacrawler,msdn,nl-telephone,nl-teletekst,python,rpmfind,tvtome,uspto,vimeo,vivisimo,voila,yahoo,yahoo_image,yahoo_local,yahoo_shopping,yahoo_video,youtube}.desktop

# Adding DuckDuckGo HTML
    cp -v duckduckgo_html.desktop "kde-runtime-${pkgver}/kurifilter-plugins/ikws/searchproviders"

# Adding DuckDuckGo Lite
    cp -v duckduckgo_lite.desktop "kde-runtime-${pkgver}/kurifilter-plugins/ikws/searchproviders"

	mkdir build
	cd build
	cmake ../kde-runtime-${pkgver} \
		-DCMAKE_BUILD_TYPE=Release \
		-DCMAKE_SKIP_RPATH=ON \
		-DCMAKE_INSTALL_PREFIX=/usr \
        -DWITH_QNtrack=OFF \
        -DWITH_Xine=OFF
	make
}

package() {
	cd "$srcdir/build"
	make DESTDIR="$pkgdir" install
	rm -f "${pkgdir}/usr/share/icons/hicolor/index.theme"

    ln -sf /usr/lib/kde4/libexec/kdesu "${pkgdir}/usr/bin/"
}