# $Id: PKGBUILD 238288 2015-04-30 08:34:07Z arojas $
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Pierre Schmitz <pierre@archlinux.de>
# Maintainer: Michał Masłowski <mtjm@mtjm.eu>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname='kdebase-konqueror'
pkgver=15.04.0
pkgrel=3.parabola1
arch=('i686' 'x86_64' 'mips64el')
url="http://kde.org/applications/internet/konqueror/"
license=('GPL' 'LGPL' 'FDL')
groups=('kde-applications' 'kdebase')
conflicts=('kdebase-nsplugins' 'kdebase-konqueror-libre')
replaces=('kdebase-nsplugins' 'kdebase-konqueror-libre')
makedepends=('kdelibs' 'cmake' 'automoc4' 'tidyhtml' 'baloo4-widgets')
source=("http://download.kde.org/stable/applications/${pkgver}/src/kde-baseapps-${pkgver}.tar.xz"
        'konq-about-fsdg.diff' 'dolphin-places.patch')
sha1sums=('18ec78a547ca68b110d3b82a12a0001bf62d0b66'
          'd6cbb53c04179b8180f9439eca156b7ff2e76b3a'
          'a3c0536eece94ac288184ceaed3b6bde9241f2dc')
pkgdesc='KDE File Manager & Web Browser, without Google and nonfree software recommendation'
depends=('kdebase-dolphin' 'kdebase-keditbookmarks')
optdepends=('kwebkitpart: to enable webkit engine')
install='kdebase-konqueror.install'

prepare() {
  mkdir build

  cd kde-baseapps-${pkgver}
  # Don't recommend nonfree software or Google.
  patch -Np1 -i "${srcdir}/konq-about-fsdg.diff"
  # Fix disappearing bookmarks in Dolphin https://bugs.kde.org/show_bug.cgi?id=345174
  patch -p1 -i "$srcdir"/dolphin-places.patch
}

build() {
  cd build
  cmake ../kde-baseapps-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_SKIP_RPATH=ON \
    -DCMAKE_INSTALL_PREFIX=/usr

  for i in konqueror doc/konqueror nsplugins; do
      cd $srcdir/build/${i}
      make
  done
}

package() {
  for i in konqueror doc/konqueror nsplugins; do
      cd $srcdir/build/${i}
      make DESTDIR=$pkgdir install
  done
}