# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=jedit
pkgver=5.3.0
pkgrel=1.parabola1
pkgdesc='Text editor for programmers'
arch=('any')
url='http://www.jedit.org/'
license=('GPL')
depends=('java-runtime')
makedepends=('apache-ant' 'apache-ant-contrib' 'apache-ivy' 'beanshell2'
             'gendesk' 'java-hamcrest' 'jsr305' 'junit')
optdepends=('java-environment: for java development'
            'ttf-fira-mono: usable font')
options=('!emptydirs')
install=$pkgname.install
source=("http://sourceforge.net/projects/$pkgname/files/$pkgname/$pkgver/jedit${pkgver}source.tar.bz2"
        'jedit.sh'
        'jeditbg.sh'
        'jedit.props'
        'jedit-fix_build.patch')
sha256sums=('8d56d036be4dd45254748f063ade01293b862a615cdff6aed274ab58085f6304'
            'b2e5a8f2f4818b336b5d71f677114f1bc01e929d7fa60918675cc2234dae1a3a'
            'a1dd1b688f08c5c967861fe80df13cac201afa6dcfcecc9a289b2c3bec7c8915'
            '1a8c6e51810abc9ff56606b61042e2e980cb4b479fa0099b3c93acd7e4b9295b'
            '6e582bf78458783fcc620d2a850474d2eb787ecf2e3950031ec4bdda48cafeb9')

prepare() {
  gendesk -f -n --pkgname "$pkgname" --pkgdesc "$pkgdesc" --exec 'jeditbg %U' \
    --name 'jEdit' --genericname 'Editor'

  cd jEdit
  mkdir -p lib/{ant-contrib,compile,ivy,default-plugins,scripting,test}
  ln -sf /usr/share/java/ant-contrib.jar lib/ant-contrib/ant-contrib.jar
  ln -sf /usr/share/java/bsh.jar lib/ant-contrib/bsh.jar
  ln -sf /usr/share/java/hamcrest-core.jar lib/test/hamcrest-core.jar
  ln -sf /usr/share/java/hamcrest-library.jar lib/test/hamcrest-library.jar
  ln -sf /usr/share/java/jsr305.jar lib/compile/jsr305.jar
  ln -sf /usr/share/java/junit.jar lib/test/junit.jar
  patch -Np1 -i "${srcdir}/jedit-fix_build.patch"
}

build() {
  cd jEdit
  ant build \
    -lib /usr/share/java/apache-ivy/ivy.jar \
    -Divy.done=true
}

package() {
  cd jEdit

  # Install license file
  install -Dm644 doc/COPYING.txt "$pkgdir/usr/share/licenses/$pkgname/COPYING.txt"
  install -Dm644 doc/COPYING.PLUGINS.txt "$pkgdir/usr/share/licenses/$pkgname/COPYING.PLUGINS.txt"
  install -Dm644 doc/COPYING.DOC.txt "$pkgdir/usr/share/licenses/$pkgname/COPYING.DOC.txt"

  # Install documentation
  install -m755 -d "$pkgdir/usr/share/java/$pkgname"
  cp -ru doc "$pkgdir/usr/share/java/$pkgname/doc"
#  install -d "$pkgdir/usr/share/doc/$pkgname"
#  cp -r build/javadoc "${pkgdir}/usr/share/doc/${pkgname}"

  # Install jars
  install -D -m644 build/$pkgname.jar "$pkgdir/usr/share/java/$pkgname/$pkgname.jar"

  # Install keymaps
  cp -r build/keymaps "${pkgdir}/usr/share/java/${pkgname}"

  # Install macros
  cp -r build/macros "${pkgdir}/usr/share/java/${pkgname}"

  # Install modes
  cp -r build/modes "${pkgdir}/usr/share/java/${pkgname}"

  # Install properties
  cp -r build/properties "${pkgdir}/usr/share/java/${pkgname}"

  # Install startup
  cp -r build/startup "${pkgdir}/usr/share/java/${pkgname}"

  # Man pages
  install -Dm644 package-files/linux/$pkgname.1 "$pkgdir/usr/share/man/man1/$pkgname.1"

  # Launchers, properties and desktop shortcuts
  install -d "$pkgdir/usr/bin"
  install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
  install -Dm755 "$srcdir/${pkgname}bg.sh" "$pkgdir/usr/bin/${pkgname}bg"
  install -Dm644 "$srcdir/$pkgname.props" "$pkgdir/usr/share/$pkgname/default.props"
  install -Dm644 "$srcdir/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 doc/$pkgname.png "$pkgdir/usr/share/pixmaps/$pkgname.png"
}