# Maintainer (arch): Bruno Pagani <archange@archlinux.org>
# Contributor: Baptiste Jonglez <baptiste--aur at jonglez dot org>


# parabola changes and rationale:
#  - no changes
#  - temporary 'jami-qt' build without qt6-webengine
#    the next jami release should have this VCS change;
#    so the arch pckage will be FDSG-fit then
#  - NOTE: this is built from VCS; but so was the
#    latest arch package - AFAIK, this should be
#    named 'jami-qt-git' - it is a one-time
#    blacklist replacement though; so it is less
#    troublesome to keep the arch pkgname
#  - NOTE: jami-{daemon,libclient,qt} versions are all tightly coupled,
#          even at the VCS level
#          implied build order: jami-daemon <- jami-libclient <- jami-qt


pkgname=jami-libclient
pkgver=20220505
pkgrel=1
pkgrel+=.parabola1
pkgdesc="Free and universal communication platform which preserves the users’ privacy and freedoms (client communication library)"
arch=(x86_64)
url="https://jami.net"
license=(GPL3)
groups=(jami)
depends=(jami-daemon qt6-base)
makedepends=(git cmake qt6-tools)
provides=(libjamiclient)
conflicts=(libjamiclient)
replaces=(libjamiclient)
_commit=c5bca2933fb02ef7f81e8fe0772801a4f97fd1f5
source=(git+https://git.jami.net/savoirfairelinux/jami-libclient.git#commit=${_commit})
md5sums=(SKIP)

# pkgver() {
#   cd ${pkgname}
#   TZ=UTC git show -s --pretty=%cd --date=format-local:%Y%m%d HEAD
# }

build() {
  cmake -B build -S jami-libclient \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make -C build
}

package() {
  make -C build DESTDIR="${pkgdir}" install
}