# $Id: PKGBUILD 100111 2010-11-20 11:25:37Z pierre $
# Maintainer: Thomas Bächler <thomas@archlinux.org>
# Maintainer: Aaron Griffin <aaron@archlinux.org>
# Maintainer (Parabola): fauno <fauno@kiwwwi.com.ar>

pkgname=initscripts
pkgver=2011.02.1
pkgrel=1
pkgdesc="System initialization/bootup scripts (Parabola branding)"
arch=('i686' 'x86_64')
url="http://parabolagnulinux.org"
license=('GPL')
groups=('base')
backup=(etc/inittab etc/rc.conf etc/rc.local etc/rc.local.shutdown etc/conf.d/wireless)
depends=('bash' 'awk' 'grep' 'coreutils' 'sed' 'udev'
         'net-tools' 'ncurses' 'kbd' 'findutils' 'sysvinit')
optdepends=('bridge-utils: Network bridging support'
            'dhcpcd: DHCP network configuration'
            'wireless_tools: Wireless networking')
install=initscripts.install
source=("ftp://ftp.archlinux.org/other/initscripts/${pkgname}-${pkgver}.tar.xz"
        'wireless.conf.d'
        'parabola-branding.patch')
md5sums=('22dcf8fc052deef0894d5caa0981419a'
         '027576534885b8d5dded9be546057b12'
         '030deb770293ea5a1e632934095af412')

package() {
  cd ${srcdir}/${pkgname}-${pkgver}

  msg2 "Rebranding for Parabola"
  patch -Np1 -i ${srcdir}/parabola-branding.patch

  DESTDIR=${pkgdir} ./install.sh
  install -D -m644 ${srcdir}/wireless.conf.d ${pkgdir}/etc/conf.d/wireless
}