# $Id: PKGBUILD 170778 2016-04-12 16:25:28Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Eschwartz <eschwartz93@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=iceweasel-noscript
pkgver=2.9.0.11
pkgrel=1
pkgdesc="Extension for iceweasel which disables script"
arch=('any')
url="http://noscript.net/"
license=('GPL2')
groups=('iceweasel-addons')
depends=('iceweasel')
makedepends=('unzip')
replaces=('firefox-noscript')
source=(https://secure.informaction.com/download/releases/noscript-${pkgver}.xpi)
noextract=("noscript-${pkgver}.xpi")
md5sums=('2344f7bab216ee3f552cbf723ad50d7b')

prepare() {
  cd "${srcdir}"
  unzip -qqo "noscript-${pkgver}.xpi" -d "noscript-${pkgver}"
}

package() {
  cd "${srcdir}"

  _extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' noscript-${pkgver}/install.rdf)"
  _extension_dest="${pkgdir}/usr/lib/iceweasel/browser/extensions/${_extension_id}"
  if grep '<em:unpack>true</em:unpack>' noscript-${pkgver}/install.rdf > /dev/null; then
    install -dm755 "${_extension_dest}"
    cp -R noscript-${pkgver}/* "${_extension_dest}"
    chmod -R ugo+rX "${_extension_dest}"
  else
    install -Dm644 noscript-${pkgver}.xpi "${_extension_dest}.xpi"
  fi
}